Example of dispatching on an interface

[csvance]

This package has been quite helpful to test my interfaces that exist within a standard type hierarchy. Ie I have a top level abstract type the interface is defined on, then concrete types that inherit the abstract type and implement the interface. To dispatch on this I can just dispatch on the top level abstract type just like I would without Interfaces.jl. But it's not clear to me exactly how interfaces can be dispatched on outside of this. I see there are some functions inside the package like implemented_trait which produces a value:

julia> Interfaces.implemented_trait(MMISpineInterpolation.SpineInterpolatorInterface, SpineInterpolator)
Interfaces.Implemented{MMISpineInterpolation.SpineInterpolatorInterface}()

Presumably I can dispatch on this somehow even if my types do not inherit the abstract type my interface was defined on. But it's not clear to me what expression/syntax I need to check where a type T in a method declaration implements an interface. I have tried many different approaches, but I've been spinning my wheels for a few hours now and not making progress.

[rafaqz]

Its for a "holy trait" setup:

myfunc(x) = myfunc(Interfaces.implemented_trait(MMISpineInterpolation.SpineInterpolatorInterface, x), x)
myfunc(::Implemented{SpineInterpolatationInterface}, x) = do_spine_thing(x)
myfunc(::NotImplemented, x) = do_default_thing(x)

Or similar. Probably not correct syntax.

[csvance]

Thank you for the pointer. This seems to work:

using Interfaces

struct ImplementsInterfaceOne end
struct ImplementsInterfaceTwo end


components = (
    mandatory = (
    ),
    optional = (
    )
)

@interface IInterface Any components "Description"

@implements IInterface ImplementsInterfaceOne [ImplementsInterfaceOne()]
@implements IInterface ImplementsInterfaceTwo [ImplementsInterfaceTwo()]

myfunc(x) = myfunc(Interfaces.implemented_trait(IInterface, x), x)
myfunc(::Interfaces.Implemented{IInterface}, x) = true
myfunc(::Interfaces.NotImplemented, x) = false

@info myfunc(ImplementsInterfaceOne())
@info myfunc(ImplementsInterfaceTwo())
@info myfunc("Squirel")

[ Info: true
[ Info: true
[ Info: false

julia> @code_llvm myfunc(ImplementsInterfaceOne())

; Function Signature: myfunc(Main.ImplementsInterfaceOne)
;  @ /home/cvance/Git/Interfaces/test.jl:20 within `myfunc`
define i8 @julia_myfunc_9847() #0 {
top:
;  @ /home/cvance/Git/Interfaces/test.jl within `myfunc`
  ret i8 1
}