[hipDNN] Use regular FlatBuffers dependency install (ROCm#8092)

## Summary

This PR follows up on [PR
ROCm#8026](ROCm#8026) by removing
`hipdnn_flatbuffers_sdk`'s standalone/local dependency vendoring path.
Fetched FlatBuffers now participates in the normal dependency install
flow, and the installed flatbuffers SDK package resolves FlatBuffers
through `find_dependency(flatbuffers REQUIRED)` instead of exporting or
copying dependency headers itself.

## Risk Assessment

Medium risk. This changes standalone hipDNN install/package layout for
locally fetched FlatBuffers, but keeps the build-time dependency
resolution model and consumer CMake dependency declarations intact;
focused install and external-consumer validation passed for both
local-fetch and `/opt/rocm` FlatBuffers paths.

## Testing Summary

- Verified standalone hipDNN configure/build/install with local
FlatBuffers and nlohmann fetch forced by disabling system package
lookup.
- Verified standalone hipDNN configure/build/install with FlatBuffers
resolved from `/opt/rocm` and nlohmann fetched locally.
- Confirmed installed package layout keeps dependency package
configs/headers separate from `hipdnn_flatbuffers_sdk` and exports only
the hipDNN target.
- Verified external installed-package consumers configure/build against
`hipdnn_flatbuffers_sdk` and `hipdnn_frontend`, including the
`/opt/rocm` FlatBuffers path.

## Testing Checklist

- [x] Standalone local-fetch configure - `cmake -G Ninja
-DCMAKE_DISABLE_FIND_PACKAGE_flatbuffers=TRUE
-DCMAKE_DISABLE_FIND_PACKAGE_nlohmann_json=TRUE
-DCMAKE_INSTALL_PREFIX=/tmp/hipdnn-install
/home/sareeder/ROCm-workspace/repos/rocm-libraries/projects/hipdnn` -
ASICs: gfx90a - Status: Passed
- [x] Standalone local-fetch build/install - `cd /tmp/hipdnn-build &&
ninja && cmake --install .` - ASICs: gfx90a - Status: Passed
- [x] Installed package layout validation - checked dependency package
configs/headers, absence of vendored dependency headers under
`include/hipdnn/flatbuffers_sdk`, and
`hipdnn_flatbuffers_sdkTargets.cmake` exporting only
`hipdnn_flatbuffers_sdk` - Status: Passed
- [x] Installed consumer configure/build - `cd /tmp/test-consumer-build
&& cmake -G Ninja /tmp/test-consumer && ninja` - ASICs: gfx90a - Status:
Passed
- [x] `/opt/rocm` FlatBuffers build/install and consumer - Docker
`hipdnn_env:fullbuild_20260602_gfx90a`; hipDNN configured with
`-DCMAKE_PREFIX_PATH=/opt/rocm`, installed, then consumer
configured/built/run with
`-DCMAKE_PREFIX_PATH="/tmp/hipdnn-optfb-install;/opt/rocm"` - Status:
Passed
- [ ] PR CI - GitHub PR checks - Status: Pending

## Technical Changes

- Removes `hipdnn_flatbuffers_sdk` local dependency export/include
bundling machinery and deletes the local-only package config template.
- Exports and installs only the `hipdnn_flatbuffers_sdk` target from
`hipdnn_flatbuffers_sdkTargets.cmake`.
- Uses the installed-package `flatbuffers::flatbuffers` target spelling
during local fetch builds by aliasing the fetched `FlatBuffers` target
for build-time include propagation.
- Enables regular FlatBuffers install participation in
`Dependencies.cmake` by building/installing the FlatBuffers package
target and not excluding the fetched subdirectory from parent install
rules.

Author: SamuelReeder

projects/hipdnn/cmake/Dependencies.cmake

@@ -177,7 +177,7 @@ function(_fetch_flatbuffers VERSION HASH)
 
     set(FLATBUFFERS_BUILD_FLATC ON)
     set(FLATBUFFERS_INSTALL ON)
-    set(FLATBUFFERS_BUILD_FLATLIB OFF)
+    set(FLATBUFFERS_BUILD_FLATLIB ON)
     set(FLATBUFFERS_BUILD_TESTS OFF)
     set(FLATBUFFERS_BUILD_FLATHASH OFF)
     set(FLATBUFFERS_ENABLE_PCH ON)
@@ -199,11 +199,6 @@ function(_fetch_flatbuffers VERSION HASH)
     _restore_var(FLATBUFFERS_BUILD_FLATHASH)
     _restore_var(FLATBUFFERS_ENABLE_PCH)
 
-    set(HIP_DNN_FLATBUFFERS_INCLUDE_DIR ${flatbuffers_SOURCE_DIR}/include
-        CACHE PATH "Path to flatbuffers include"
-    )
-
-    _exclude_from_all(${flatbuffers_SOURCE_DIR})
     _mark_targets_as_system(${flatbuffers_SOURCE_DIR})
 endfunction()
 

projects/hipdnn/flatbuffers_sdk/CMakeLists.txt

@@ -49,57 +49,13 @@ if(NOT HIPDNN_FLATBUFFERS_SDK_SKIP_JSON_LIB AND NOT TARGET nlohmann_json::nlohma
     hipdnn_add_dependency(nlohmann_json VERSION ${HIPDNN_NLOHMANN_JSON_VERSION})
 endif()
 
-# --- Dependency processing ---
-set(_hipdnn_flatbuffers_sdk_local_export_targets)
-set(_hipdnn_flatbuffers_sdk_local_export_includes)
 
-# Function to process flatbuffers_sdk dependencies and populate local export lists.
-# TARGET_NAME - The actual target name (e.g., FlatBuffers)
-# ALIAS_NAME  - The alias target name (e.g., flatbuffers::flatbuffers)
-# INCLUDE_DIR - Optional parent include directory to bundle with the install
-function(_hipdnn_flatbuffers_sdk_process_dependency TARGET_NAME ALIAS_NAME)
-    set(options "")
-    set(oneValueArgs INCLUDE_DIR)
-    set(multiValueArgs "")
-    cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
-
-    if(NOT TARGET ${TARGET_NAME})
-        return()
-    endif()
-
-    if(NOT TARGET ${ALIAS_NAME})
-        add_library(${ALIAS_NAME} ALIAS ${TARGET_NAME})
-    endif()
-
-    get_target_property(_is_imported ${TARGET_NAME} IMPORTED)
-    if(NOT _is_imported)
-        list(APPEND _hipdnn_flatbuffers_sdk_local_export_targets ${TARGET_NAME})
-        set(_hipdnn_flatbuffers_sdk_local_export_targets ${_hipdnn_flatbuffers_sdk_local_export_targets} PARENT_SCOPE)
-
-        if(ARG_INCLUDE_DIR)
-            list(APPEND _hipdnn_flatbuffers_sdk_local_export_includes ${ARG_INCLUDE_DIR})
-            set(_hipdnn_flatbuffers_sdk_local_export_includes ${_hipdnn_flatbuffers_sdk_local_export_includes} PARENT_SCOPE)
-        endif()
-    endif()
-endfunction()
-
-if(TARGET FlatBuffers)
-    # Workaround: flatbuffers sets INSTALL_INTERFACE to include/include which resolves incorrectly.
-    # Force it to the correct install path for hipdnn_flatbuffers_sdk.
-    get_target_property(_is_imported FlatBuffers IMPORTED)
-    if(NOT _is_imported)
-        get_target_property(current_includes FlatBuffers INTERFACE_INCLUDE_DIRECTORIES)
-        list(REMOVE_ITEM current_includes "$<INSTALL_INTERFACE:include/include>")
-        list(APPEND current_includes "$<INSTALL_INTERFACE:${HIP_DNN_FLATBUFFERS_SDK_INSTALL_INCLUDE_DIR}>")
-        set_target_properties(
-            FlatBuffers PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "${current_includes}"
-        )
-    endif()
-    _hipdnn_flatbuffers_sdk_process_dependency(
-        FlatBuffers flatbuffers::flatbuffers INCLUDE_DIR ${HIP_DNN_FLATBUFFERS_INCLUDE_DIR}
-    )
+# Upstream FlatBuffers exposes FlatBuffers when fetched via add_subdirectory,
+# while its installed package exposes flatbuffers::flatbuffers. Use the installed-package
+# spelling internally so the build and exported config follow the same dependency model.
+if(TARGET FlatBuffers AND NOT TARGET flatbuffers::flatbuffers)
+    add_library(flatbuffers::flatbuffers ALIAS FlatBuffers)
 endif()
-
 # --- Create the library target ---
 add_library(hipdnn_flatbuffers_sdk INTERFACE)
 
@@ -180,13 +136,11 @@ if(HIPDNN_GENERATE_SDK_HEADERS)
 endif()
 
 # --- Export and install ---
-export(TARGETS hipdnn_flatbuffers_sdk ${_hipdnn_flatbuffers_sdk_local_export_targets}
+export(TARGETS hipdnn_flatbuffers_sdk
        FILE "${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR}/cmake/hipdnn_flatbuffers_sdk/hipdnn_flatbuffers_sdkTargets.cmake"
 )
 
-install(TARGETS hipdnn_flatbuffers_sdk ${_hipdnn_flatbuffers_sdk_local_export_targets}
-        EXPORT hipdnn_flatbuffers_sdk_targets COMPONENT Development
-)
+install(TARGETS hipdnn_flatbuffers_sdk EXPORT hipdnn_flatbuffers_sdk_targets COMPONENT Development)
 
 # cmake-lint: disable=E1122
 install(
@@ -210,30 +164,11 @@ install(EXPORT hipdnn_flatbuffers_sdk_targets DESTINATION ${CMAKE_INSTALL_LIBDIR
         FILE hipdnn_flatbuffers_sdkTargets.cmake COMPONENT Development
 )
 
-# Install behavior depends on local vs imported dependencies
-if(_hipdnn_flatbuffers_sdk_local_export_includes)
-    # cmake-lint: disable=E1122
-    install(
-        DIRECTORY ${_hipdnn_flatbuffers_sdk_local_export_includes}/
-        DESTINATION ${HIP_DNN_FLATBUFFERS_SDK_INSTALL_INCLUDE_DIR}
-        COMPONENT Development
-        FILES_MATCHING
-        PATTERN "*.h"
-        PATTERN "*.hpp"
-        PATTERN "codegen" EXCLUDE
-    )
-    configure_package_config_file(
-        "${CMAKE_CURRENT_SOURCE_DIR}/cmake/hipdnn_flatbuffers_sdkConfig_local.cmake.in"
-        "${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR}/cmake/hipdnn_flatbuffers_sdk/hipdnn_flatbuffers_sdkConfig.cmake"
-        INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/hipdnn_flatbuffers_sdk
-    )
-else()
-    configure_package_config_file(
-        "${CMAKE_CURRENT_SOURCE_DIR}/cmake/hipdnn_flatbuffers_sdkConfig_imported.cmake.in"
-        "${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR}/cmake/hipdnn_flatbuffers_sdk/hipdnn_flatbuffers_sdkConfig.cmake"
-        INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/hipdnn_flatbuffers_sdk
-    )
-endif()
+configure_package_config_file(
+    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/hipdnn_flatbuffers_sdkConfig.cmake.in"
+    "${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR}/cmake/hipdnn_flatbuffers_sdk/hipdnn_flatbuffers_sdkConfig.cmake"
+    INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/hipdnn_flatbuffers_sdk
+)
 
 # Generate package version file for find_package version checking
 write_basic_package_version_file(

…_flatbuffers_sdkConfig_imported.cmake.in …ke/hipdnn_flatbuffers_sdkConfig.cmake.inprojects/hipdnn/flatbuffers_sdk/cmake/hipdnn_flatbuffers_sdkConfig_imported.cmake.in renamed to projects/hipdnn/flatbuffers_sdk/cmake/hipdnn_flatbuffers_sdkConfig.cmake.in projects/hipdnn/flatbuffers_sdk/cmake/hipdnn_flatbuffers_sdkConfig_imported.cmake.in renamed to projects/hipdnn/flatbuffers_sdk/cmake/hipdnn_flatbuffers_sdkConfig.cmake.in

@@ -2,8 +2,8 @@
 # SPDX-License-Identifier:  MIT
 
 # Shared FlatBuffers version validation, used by both the in-tree
-# flatbuffers_sdk/CMakeLists.txt at build time and by the installed imported
-# Config (hipdnn_flatbuffers_sdkConfig_imported.cmake.in) at consumer
+# flatbuffers_sdk/CMakeLists.txt at build time and by the installed
+# hipdnn_flatbuffers_sdkConfig.cmake package config at consumer
 # find_package() time. Single-sourcing the comparison and core message keeps
 # the two call sites from drifting.
 #