crux/examples/notes/Justfile at master · redbadger/crux · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
mod lib '../../lib.just'

default: dev

shells := "shared web-nextjs"

# checks required tools across all shells
[script('bash')]
doctor:
    for shell in {{ shells }}; do
        echo '{{ style("command") }}'"$shell"':{{ NORMAL }}'
        just "$shell/doctor"
        echo ''
    done

# local development workflow
[script('bash')]
dev:
    for shell in {{ shells }}; do
        echo '{{ style("command") }}'"$shell"'/dev:{{ NORMAL }}'
        just "$shell/dev"
    done

# fix formatting in all shells
[script('bash')]
fix:
    set -euo pipefail
    for shell in {{ shells }}; do
        echo '{{ style("command") }}'"$shell"'/fix:{{ NORMAL }}'
        just "$shell/fix"
    done

# clean build artefacts in all shells
[script('bash')]
clean:
    for shell in {{ shells }}; do
        echo '{{ style("command") }}'"$shell"'/clean:{{ NORMAL }}'
        just "$shell/clean"
    done

# update pnpm dependencies in all pnpm shells
[script('bash')]
update-pnpm-deps:
    set -euo pipefail
    just web-nextjs/update-pnpm-deps

# CI workflow
[script('bash')]
ci:
    for shell in {{ shells }}; do
        echo '{{ style("command") }}'"$shell"'/ci:{{ NORMAL }}'
        just "$shell/ci"
    done