include android and ios example modules only when their tasks are called

Author: riccardobl

build.gradle

@@ -85,6 +85,30 @@ tasks.register('run') {
     description = 'Run the jME3 examples'
 }
 
+tasks.register('runAndroidExamples') {
+    description = 'Run the Android examples selector'
+    def androidExamplesProject = findProject(':jme3-android-examples')
+    if (androidExamplesProject != null) {
+        dependsOn ':jme3-android-examples:runAndroidExamples'
+    } else {
+        doLast {
+            throw new GradleException('Android examples are not available. Request an Android examples task and configure an Android SDK.')
+        }
+    }
+}
+
+tasks.register('runIosExamples') {
+    description = 'Run the iOS examples selector'
+    def iosExamplesProject = findProject(':jme3-ios-examples')
+    if (iosExamplesProject != null) {
+        dependsOn ':jme3-ios-examples:runIosExamples'
+    } else {
+        doLast {
+            throw new GradleException('iOS examples are not available. Request an iOS examples task.')
+        }
+    }
+}
+
 defaultTasks 'run'
 
 def libDist = tasks.register('libDist') {

settings.gradle

@@ -17,7 +17,22 @@ plugins {
 rootProject.name = 'jmonkeyengine'
 
 def androidExamplesMinCompileSdk = 34
-def isMacOs = System.getProperty('os.name').toLowerCase(Locale.ROOT).contains('mac')
+def isAndroidExamplesTaskRequested = {
+    gradle.startParameter.taskNames.any { taskName ->
+        taskName == 'runAndroidExamples'
+            || taskName == ':runAndroidExamples'
+            || taskName == 'jme3-android-examples'
+            || taskName.startsWith(':jme3-android-examples:')
+    }
+}
+def isIosExamplesTaskRequested = {
+    gradle.startParameter.taskNames.any { taskName ->
+        taskName == 'runIosExamples'
+            || taskName == ':runIosExamples'
+            || taskName == 'jme3-ios-examples'
+            || taskName.startsWith(':jme3-ios-examples:')
+    }
+}
 
 def findAndroidSdk = {
     def sdkDirs = []
@@ -94,13 +109,15 @@ include 'jme3-testdata'
 include 'jme3-examples'
 include 'jme3-awt-dialogs'
 
-def androidSdk = findAndroidSdk()
-if (androidSdk != null) {
-    System.setProperty('android.home', androidSdk.dir.absolutePath)
-    gradle.ext.androidExamplesCompileSdk = androidSdk.compileSdk
-    include 'jme3-android-examples'
+if (isAndroidExamplesTaskRequested()) {
+    def androidSdk = findAndroidSdk()
+    if (androidSdk != null) {
+        System.setProperty('android.home', androidSdk.dir.absolutePath)
+        gradle.ext.androidExamplesCompileSdk = androidSdk.compileSdk
+        include 'jme3-android-examples'
+    }
 }
-if (isMacOs) {
+if (isIosExamplesTaskRequested()) {
     include 'jme3-ios-examples'
 }
 include 'jme3-screenshot-tests'