feat: enhance reward percentage validation in ConfigurationTest with boundary checks

Author: Hakob23

test/collateral/Configuration.t.sol

@@ -3,7 +3,9 @@ pragma solidity 0.8.25;
 
 import {CollateralTestBase} from "./CollateralTestBase.sol";
 import {CollateralManagementContract} from "../../src/CollateralManagement.sol";
+import {ICollateralManagement} from "../../src/interfaces/ICollateralManagement.sol";
 import {IAccessControl} from "@openzeppelin/contracts/access/IAccessControl.sol";
+import {ERC1967Proxy} from "@openzeppelin/contracts/proxy/ERC1967/ERC1967Proxy.sol";
 import {Flyover} from "../../src/libraries/Flyover.sol";
 
 contract ConfigurationTest is CollateralTestBase {
@@ -94,6 +96,63 @@ contract ConfigurationTest is CollateralTestBase {
         );
     }
 
+    function test_Initialize_RevertsWhenRewardPercentageExceedsMaximum()
+        public
+    {
+        uint256 invalidRewardPercentage = collateralManagement
+            .TOTAL_REWARD_PERCENTAGE() + 1;
+        CollateralManagementContract implementation = new CollateralManagementContract();
+        bytes memory initData = abi.encodeCall(
+            CollateralManagementContract.initialize,
+            (
+                owner,
+                TEST_DEFAULT_ADMIN_DELAY,
+                TEST_MIN_COLLATERAL,
+                TEST_RESIGN_DELAY_BLOCKS,
+                invalidRewardPercentage
+            )
+        );
+
+        vm.expectRevert(
+            abi.encodeWithSelector(
+                ICollateralManagement.InvalidRewardPercentage.selector,
+                collateralManagement.TOTAL_REWARD_PERCENTAGE(),
+                invalidRewardPercentage
+            )
+        );
+        new ERC1967Proxy(address(implementation), initData);
+    }
+
+    function test_Initialize_AllowsMaximumBoundary() public {
+        uint256 maxRewardPercentage = collateralManagement
+            .TOTAL_REWARD_PERCENTAGE();
+        CollateralManagementContract implementation = new CollateralManagementContract();
+        bytes memory initData = abi.encodeCall(
+            CollateralManagementContract.initialize,
+            (
+                owner,
+                TEST_DEFAULT_ADMIN_DELAY,
+                TEST_MIN_COLLATERAL,
+                TEST_RESIGN_DELAY_BLOCKS,
+                maxRewardPercentage
+            )
+        );
+
+        ERC1967Proxy proxy = new ERC1967Proxy(
+            address(implementation),
+            initData
+        );
+        CollateralManagementContract collateralManagementWithMaxReward = CollateralManagementContract(
+                payable(address(proxy))
+            );
+
+        assertEq(
+            collateralManagementWithMaxReward.getRewardPercentage(),
+            maxRewardPercentage,
+            "Initialize should accept maximum basis points value"
+        );
+    }
+
     // ============ setRewardPercentage function tests ============
 
     function test_SetRewardPercentage_OnlyAllowsOwnerToModify() public {
@@ -130,6 +189,51 @@ contract ConfigurationTest is CollateralTestBase {
         );
     }
 
+    function test_SetRewardPercentage_RevertsWhenExceedingMaximum() public {
+        uint256 initialRewardPercentage = collateralManagement
+            .getRewardPercentage();
+        uint256 invalidRewardPercentage = collateralManagement
+            .TOTAL_REWARD_PERCENTAGE() + 1;
+
+        vm.startPrank(owner);
+        vm.expectRevert(
+            abi.encodeWithSelector(
+                ICollateralManagement.InvalidRewardPercentage.selector,
+                collateralManagement.TOTAL_REWARD_PERCENTAGE(),
+                invalidRewardPercentage
+            )
+        );
+        collateralManagement.setRewardPercentage(invalidRewardPercentage);
+        vm.stopPrank();
+
+        assertEq(
+            collateralManagement.getRewardPercentage(),
+            initialRewardPercentage,
+            "RewardPercentage should remain unchanged after revert"
+        );
+    }
+
+    function test_SetRewardPercentage_AllowsMaximumBoundary() public {
+        uint256 oldRewardPercentage = collateralManagement
+            .getRewardPercentage();
+        uint256 maxRewardPercentage = collateralManagement
+            .TOTAL_REWARD_PERCENTAGE();
+
+        vm.prank(owner);
+        vm.expectEmit(true, true, false, false);
+        emit CollateralManagementContract.RewardPercentageSet(
+            oldRewardPercentage,
+            maxRewardPercentage
+        );
+        collateralManagement.setRewardPercentage(maxRewardPercentage);
+
+        assertEq(
+            collateralManagement.getRewardPercentage(),
+            maxRewardPercentage,
+            "RewardPercentage should accept maximum basis points value"
+        );
+    }
+
     // ============ setResignDelayInBlocks function tests ============
 
     function test_SetResignDelayInBlocks_OnlyAllowsOwnerToModify() public {