introduce an option to drive animations with folly::dynamic (facebook#51470)

Summary:

changelog: [internal]

To support C++ Native Animated and prevent unnecessary conversion between `folly::dynamic` <-> and `NSDictionary`, a method to apply `folly::dynamic` changes needs to be exposed on RCTMountingManager.

Previously I tried to change existing method `synchronouslyUpdateViewOnUIThread` to take folly::dynamic instead of `NSDictionary`. However this requires a change where we would expose C++ API to Objective-C class only, breaking build system in open source. This approach was backed out in  D74881580.

In this diff, I take an alternative approach and expose two methods to apply animation changes: 
- Keep the existing API `synchronouslyUpdateViewOnUIThread` as is. This way, Objective-C Native Animated does not need to change.
- Introduce new method for `[RCTSurfacePresenter schedulerDidSynchronouslyUpdateViewOnUIThread]` which accepts `folly::dynamic`. This is used by C++ Native Animated only

Differential Revision: D74885607

Author: sammy-SC

packages/react-native/React/Fabric/Mounting/RCTMountingManager.h

@@ -67,7 +67,7 @@ NS_ASSUME_NONNULL_BEGIN
            forShadowView:(const facebook::react::ShadowView &)shadowView;
 
 - (void)synchronouslyUpdateViewOnUIThread:(ReactTag)reactTag
-                             changedProps:(NSDictionary *)props
+                             changedProps:(folly::dynamic)props
                       componentDescriptor:(const facebook::react::ComponentDescriptor &)componentDescriptor;
 @end
 

packages/react-native/React/Fabric/Mounting/RCTMountingManager.mm

@@ -282,25 +282,34 @@ - (void)setIsJSResponder:(BOOL)isJSResponder
 }
 
 - (void)synchronouslyUpdateViewOnUIThread:(ReactTag)reactTag
-                             changedProps:(NSDictionary *)props
+                             changedProps:(folly::dynamic)props
                       componentDescriptor:(const ComponentDescriptor &)componentDescriptor
 {
   RCTAssertMainQueue();
+  NSArray<NSString *> *propsKeysToBeUpdated = extractKeysFromFollyDynamic(props);
+  bool updatesTransform = props.find("transform") != props.items().end();
+  bool updatesOpacity = props.find("opacity") != props.items().end();
+
   UIView<RCTComponentViewProtocol> *componentView = [_componentViewRegistry findComponentViewWithTag:reactTag];
+  if (!componentView) {
+    RCTLogWarn(@"Attempted to update view with tag %ld, but it no longer exists", (long)reactTag);
+    return;
+  }
+
   SurfaceId surfaceId = RCTSurfaceIdForView(componentView);
   Props::Shared oldProps = [componentView props];
   Props::Shared newProps = componentDescriptor.cloneProps(
-      PropsParserContext{surfaceId, *_contextContainer.get()}, oldProps, RawProps(convertIdToFollyDynamic(props)));
+      PropsParserContext{surfaceId, *_contextContainer.get()}, oldProps, RawProps(std::move(props)));
 
   NSSet<NSString *> *propKeys = componentView.propKeysManagedByAnimated_DO_NOT_USE_THIS_IS_BROKEN ?: [NSSet new];
-  propKeys = [propKeys setByAddingObjectsFromArray:props.allKeys];
+  propKeys = [propKeys setByAddingObjectsFromArray:propsKeysToBeUpdated];
   componentView.propKeysManagedByAnimated_DO_NOT_USE_THIS_IS_BROKEN = nil;
   [componentView updateProps:newProps oldProps:oldProps];
   componentView.propKeysManagedByAnimated_DO_NOT_USE_THIS_IS_BROKEN = propKeys;
 
   const auto &newViewProps = static_cast<const ViewProps &>(*newProps);
 
-  if (props[@"transform"]) {
+  if (updatesTransform) {
     auto layoutMetrics = LayoutMetrics();
     layoutMetrics.frame.size.width = componentView.layer.bounds.size.width;
     layoutMetrics.frame.size.height = componentView.layer.bounds.size.height;
@@ -309,7 +318,7 @@ - (void)synchronouslyUpdateViewOnUIThread:(ReactTag)reactTag
       componentView.layer.transform = newTransform;
     }
   }
-  if (props[@"opacity"] && componentView.layer.opacity != (float)newViewProps.opacity) {
+  if (updatesOpacity && componentView.layer.opacity != (float)newViewProps.opacity) {
     componentView.layer.opacity = newViewProps.opacity;
   }
 

packages/react-native/React/Fabric/RCTSurfacePresenter.h

@@ -66,6 +66,7 @@ NS_ASSUME_NONNULL_BEGIN
 - (nullable RCTFabricSurface *)surfaceForRootTag:(ReactTag)rootTag;
 
 - (void)synchronouslyUpdateViewOnUIThread:(NSNumber *)reactTag props:(NSDictionary *)props;
+- (void)schedulerDidSynchronouslyUpdateViewOnUIThread:(ReactTag)tag props:(folly::dynamic)props;
 
 - (void)setupAnimationDriverWithSurfaceHandler:(const facebook::react::SurfaceHandler &)surfaceHandler;
 

packages/react-native/React/Fabric/RCTSurfacePresenter.mm

@@ -149,13 +149,18 @@ - (UIView *)findComponentViewWithTag_DO_NOT_USE_DEPRECATED:(NSInteger)tag
 }
 
 - (void)synchronouslyUpdateViewOnUIThread:(NSNumber *)reactTag props:(NSDictionary *)props
+{
+  ReactTag tag = [reactTag integerValue];
+  [self schedulerDidSynchronouslyUpdateViewOnUIThread:tag props:convertIdToFollyDynamic(props)];
+}
+
+- (void)schedulerDidSynchronouslyUpdateViewOnUIThread:(ReactTag)tag props:(folly::dynamic)props
 {
   RCTScheduler *scheduler = [self scheduler];
   if (!scheduler) {
     return;
   }
 
-  ReactTag tag = [reactTag integerValue];
   UIView<RCTComponentViewProtocol> *componentView =
       [_mountingManager.componentViewRegistry findComponentViewWithTag:tag];
   if (componentView == nil) {
@@ -168,7 +173,9 @@ - (void)synchronouslyUpdateViewOnUIThread:(NSNumber *)reactTag props:(NSDictiona
     return;
   }
 
-  [_mountingManager synchronouslyUpdateViewOnUIThread:tag changedProps:props componentDescriptor:*componentDescriptor];
+  [_mountingManager synchronouslyUpdateViewOnUIThread:tag
+                                         changedProps:std::move(props)
+                                  componentDescriptor:*componentDescriptor];
 }
 
 - (void)setupAnimationDriverWithSurfaceHandler:(const facebook::react::SurfaceHandler &)surfaceHandler

packages/react-native/ReactCommon/react/utils/platform/ios/react/utils/FollyConvert.h

@@ -12,6 +12,7 @@
 namespace facebook::react {
 
 folly::dynamic convertIdToFollyDynamic(id json);
-id convertFollyDynamicToId(const folly::dynamic& dyn);
+id convertFollyDynamicToId(const folly::dynamic &dyn);
+NSArray<NSString *> *extractKeysFromFollyDynamic(const folly::dynamic &dyn);
 
 } // namespace facebook::react

packages/react-native/ReactCommon/react/utils/platform/ios/react/utils/FollyConvert.mm

@@ -113,4 +113,20 @@ id convertFollyDynamicToId(const folly::dynamic &dyn)
   return nil;
 }
 
+NSArray<NSString *> *extractKeysFromFollyDynamic(const folly::dynamic &dyn)
+{
+  NSMutableArray<NSString *> *result = [NSMutableArray new];
+
+  if (dyn.type() == folly::dynamic::OBJECT) {
+    for (const auto &elem : dyn.items()) {
+      NSString *key = [[NSString alloc] initWithBytes:elem.first.c_str()
+                                               length:elem.first.size()
+                                             encoding:NSUTF8StringEncoding];
+      [result addObject:key];
+    }
+  }
+
+  return result;
+}
+
 } // namespace facebook::react