Fixed the handling of the taxdump

JSON files are not generated in the input directory any more.
Importantly, the pipeline accepts taking a JSON in too.

Author: muffato

bin/jsonify_taxdump.py

@@ -0,0 +1,27 @@
+#!/usr/bin/env python3
+
+import argparse
+import sys
+
+from blobtools.lib.file_io import write_file
+from blobtools.lib.taxdump import Taxdump
+
+
+def parse_args(args=None):
+    Description = "Parse and digest the taxdump files into a JSON structure, printed on stdout."
+
+    parser = argparse.ArgumentParser(description=Description)
+    parser.add_argument("taxdump", help="Path to the taxonomy database")
+    parser.add_argument("--version", action="version", version="%(prog)s 1.0")
+    return parser.parse_args(args)
+
+
+def main(args=None):
+    args = parse_args(args)
+
+    taxdump = Taxdump(args.taxdump)
+    write_file("STDOUT", taxdump.values_to_dict())
+
+
+if __name__ == "__main__":
+    sys.exit(main())

modules/local/blobtoolkit/createblobdir.nf

@@ -12,7 +12,7 @@ process BLOBTOOLKIT_CREATEBLOBDIR {
     tuple val(meta1), path(busco, stageAs: 'lineage??/*')
     tuple val(meta2), path(blastp)
     tuple val(meta3), path(yaml)
-    path(taxdump)
+    path(taxdump, stageAs: 'taxdump/taxdump.json')
 
     output:
     tuple val(meta), path(prefix), emit: blobdir
@@ -30,7 +30,7 @@ process BLOBTOOLKIT_CREATEBLOBDIR {
     blobtools replace \\
         --bedtsvdir windowstats \\
         --meta ${yaml} \\
-        --taxdump ${taxdump} \\
+        --taxdump \$(dirname ${taxdump}) \\
         --taxrule buscogenes \\
         ${busco_args} \\
         ${hits_blastp} \\

modules/local/blobtoolkit/updateblobdir.nf

@@ -13,7 +13,7 @@ process BLOBTOOLKIT_UPDATEBLOBDIR {
     tuple val(meta3), path(categories_tsv)
     tuple val(meta4), path(blastx, stageAs: "blastx.txt")
     tuple val(meta5), path(blastn, stageAs: "blastn.txt")
-    path(taxdump)
+    path(taxdump, stageAs: 'taxdump/taxdump.json')
 
     output:
     tuple val(meta), path(prefix), emit: blobdir
@@ -35,7 +35,7 @@ process BLOBTOOLKIT_UPDATEBLOBDIR {
     mkdir ${prefix}
     cp --preserve=timestamp ${input}/* ${prefix}/
     blobtools replace \\
-        --taxdump ${taxdump} \\
+        --taxdump \$(dirname ${taxdump}) \\
         --taxrule bestdistorder=buscoregions \\
         ${hits_blastx} \\
         ${hits_blastn} \\

modules/local/jsonify_taxdump.nf

@@ -0,0 +1,32 @@
+process JSONIFY_TAXDUMP {
+    tag "$meta.id"
+    label 'process_single'
+
+    conda "conda-forge::requests=2.28.1 conda-forge::pyyaml=6.0"
+    container "docker.io/genomehubs/blobtoolkit:4.4.4"
+
+    input:
+    tuple val(meta), path(taxdump)
+
+    output:
+    tuple val(meta), path("*.json") , emit: json
+    path "versions.yml"             , emit: versions
+
+    when:
+    task.ext.when == null || task.ext.when
+
+    script:
+    def args = task.ext.args ?: ''
+    def prefix = task.ext.prefix ?: "${meta.id}"
+    """
+    jsonify_taxdump.py \\
+        $taxdump \\
+        $args \\
+        > ${prefix}.json
+
+    cat <<-END_VERSIONS > versions.yml
+    "${task.process}":
+        jsonify_taxdump.py: \$(jsonify_taxdump.py --version | cut -d' ' -f2)
+    END_VERSIONS
+    """
+}

subworkflows/local/input_check.nf

@@ -9,6 +9,7 @@ include { UNTAR                     } from '../../modules/nf-core/untar/main'
 include { CAT_CAT                   } from '../../modules/nf-core/cat/cat/main'
 include { SAMTOOLS_FLAGSTAT         } from '../../modules/nf-core/samtools/flagstat/main'
 include { GENERATE_CONFIG           } from '../../modules/local/generate_config'
+include { JSONIFY_TAXDUMP           } from '../../modules/local/jsonify_taxdump'
 
 workflow INPUT_CHECK {
     take:
@@ -159,6 +160,32 @@ workflow INPUT_CHECK {
     | first
     | set { ch_busco_db }
 
+
+    //
+    // Convert the taxdump to a JSON file if there isn't one yet
+    //
+    ch_databases.taxdump
+    | filter { meta, db_path -> ! db_path.isFile() }
+    | map { meta, db_path -> [meta, db_path, db_path.listFiles().find { it.getName().endsWith('.json') }] }
+    | branch { meta, db_path, json_path ->
+        json: json_path
+                return [meta, json_path]
+        dir: true
+                return [meta, db_path]
+    }
+    | set { taxdump_dirs }
+
+    JSONIFY_TAXDUMP( taxdump_dirs.dir )
+    ch_versions = ch_versions.mix(JSONIFY_TAXDUMP.out.versions.first())
+
+    ch_databases.taxdump
+    | filter { meta, db_path -> db_path.isFile() }
+    | mix ( taxdump_dirs.json )
+    | mix( JSONIFY_TAXDUMP.out.json )
+    | map { _, db_path -> db_path }
+    | set { ch_taxdump }
+
+
     emit:
     reads                                   // channel: [ val(meta), path(datafile) ]
     config = GENERATE_CONFIG.out.yaml       // channel: [ val(meta), path(yaml) ]
@@ -170,7 +197,7 @@ workflow INPUT_CHECK {
     blastp = ch_databases.blastp.first()    // channel: [ val(meta), path(blastp_db) ]
     blastx = ch_databases.blastx.first()    // channel: [ val(meta), path(blastx_db) ]
     busco_db = ch_busco_db                  // channel: [ path(busco_db) ]
-    taxdump = ch_databases.taxdump.map { _, db_path -> db_path }          // channel: [ path(taxdump) ]
+    taxdump = ch_taxdump.first()            // channel: [ path(taxdump) ]
     versions = ch_versions                  // channel: [ versions.yml ]
 }
 

subworkflows/local/utils_nfcore_blobtoolkit_pipeline/main.nf

@@ -65,6 +65,10 @@ workflow PIPELINE_INITIALISATION {
         error('--align not specified, even though the input samplesheet is a nf-core/fetchngs one - i.e has fastq files!')
     }
 
+    if (file(params.taxdump).isFile() && !params.taxdump.endsWith('.json') && !params.taxdump.endsWith('.tar.gz')) {
+        error('--taxdump can take either a JSON file, a tar.gz archive, or a directory')
+    }
+
     ch_fasta = Channel.value([ [ 'id': params.accession ?: file(params.fasta.replace(".gz", "")).baseName ], file(params.fasta) ])
 
     Channel.empty()