base.config

/*
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
    sanger-tol/curationpretext Nextflow base config file
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
    A 'blank slate' config file, appropriate for general use on most high performance
    compute environments. Assumes that all software is installed and available on
    the PATH. Runs in `local` mode - all jobs will be run on the logged in environment.
----------------------------------------------------------------------------------------
*/

process {
    cpus          = { 1      * task.attempt }
    memory        = { 6.GB   * task.attempt }
    time          = { 4.h    * task.attempt }

    errorStrategy = { task.exitStatus in ((130..145) + 104 + 175) ? 'retry' : 'finish' }
    maxRetries    = 1
    maxErrors     = '-1'

    // IN CASES WHERE THERE IS ONE HIC FILE THIS WILL NEED ALMOST NOTHING
    withName:SAMTOOLS_MERGE {
        cpus    = { 16                          }
        memory  = { 50.GB     * task.attempt    }
        time    = { 30.h      * task.attempt    }
    }

    withName: '.*:.*:LONGREAD_COVERAGE:(MINIMAP2_ALIGN|MINIMAP2_ALIGN_SPLIT)' {
        cpus   = { 20   * 1 }
        memory = {
                1.GB * (
                reference.size() < 2e9 ? 30 :
                (reference.size() < 5e9 ? 40 :
                (reference.size() < 10e9 ? 60 :
                Math.ceil((reference.size() / 1e9) * 3)
                    )
                )
            ) * Math.ceil(task.attempt * 1)
        }
        time   = { 1.h  * ( reference.size() < 1e9 ? 10 : reference.size() < 10e9 ? 30 : 48) }
    }

    withName: CRAM_FILTER_ALIGN_BWAMEM2_FIXMATE_SORT {
        cpus    = { 16   * 1 }
        memory  = { 1.GB * ( reference.size() < 2e9 ? 80 : Math.ceil( ( reference.size() / 1e+9 ) * 30 ) * Math.ceil( task.attempt * 1 ) ) }
    }

    withName: CRAM_FILTER_MINIMAP2_FILTER5END_FIXMATE_SORT {
        cpus   = { 16   * 1 }
        memory = {
                1.GB * (
                reference.size() < 2e9 ? 30 :
                (reference.size() < 5e9 ? 40 :
                (reference.size() < 10e9 ? 60 :
                Math.ceil((reference.size() / 1e9) * 3)
                    )
                )
            ) * Math.ceil(task.attempt * 1)
        }
    }

    withName: PRETEXT_GRAPH {
        memory  = { 128.MB   * Math.ceil( task.attempt * 1.5 ) }
    }

    withName: PRETEXTMAP_STANDRD{
        cpus    = { 8        * 1 }
        memory  = { 3.GB     * task.attempt }
        time    = { 1.h      * ( ( fasta.size() < 4e9 ? 24 : 48 ) * task.attempt ) }
    }

    withName: PRETEXTMAP_HIGHRES {
        cpus    = {  6       * task.attempt }
        memory  = {  20.GB   * Math.ceil( task.attempt * 2.6 ) }
        time    = {  1.h     * ( ( fasta.size() < 4e9 ? 24 : 48 ) * Math.ceil( task.attempt * 1 ) ) }
    }

    withName: SNAPSHOT_SRES {
        cpus    = { 1        * task.attempt }
        memory  = { 1.GB     * task.attempt }
    }

    withName: BWAMEM2_INDEX {
        memory = { 1.GB * Math.ceil( 28 * fasta.size() / 1e+9 ) * task.attempt }
    }

    withName: MINIMAP2_INDEX {
        cpus    = {  2    * task.attempt }
        memory  = {  1.GB * Math.ceil( 4 * fasta.size() / 1e+9 ) * task.attempt }
    }

    withName: GAP_LENGTH {
        cpus   = { 1                        }
        memory = { 100.MB    * task.attempt }
    }

    // Parity with TreeVal
    // Module needs what seems like alot of memory incase the cram file contains multiple
    // read groups, in this case it needs to split the CRAM
    withName: CRAM_GENERATE_CSV {
        cpus   = { 6                        }
        memory = { 30.GB     * task.attempt }
        time   = { 10.h      * task.attempt }
    }

    withName: GNU_SORT {
        memory = { 1.GB      * task.attempt }
    }

    withName: BEDTOOLS_INTERSECT {
        memory = { 10.GB * task.attempt }
        time   = { 20.h  * task.attempt }
    }

    // Process-specific resource requirements
    // NOTE - Please try and reuse the labels below as much as possible.
    //        These labels are used and recognised by default in DSL2 files hosted on nf-core/modules.
    //        If possible, it would be nice to keep the same label naming convention when
    //        adding in your local modules too.
    // See https://www.nextflow.io/docs/latest/config.html#config-process-selectors
    withLabel:process_single {
        cpus   = { 1                   }
        memory = { 6.GB * task.attempt }
        time   = { 4.h  * task.attempt }
    }
    withLabel:process_low {
        cpus   = { 2     * task.attempt }
        memory = { 12.GB * task.attempt }
        time   = { 4.h   * task.attempt }
    }
    withLabel:process_medium {
        cpus   = { 6     * task.attempt }
        memory = { 36.GB * task.attempt }
        time   = { 8.h   * task.attempt }
    }
    withLabel:process_high {
        cpus   = { 12    * task.attempt }
        memory = { 72.GB * task.attempt }
        time   = { 16.h  * task.attempt }
    }
    withLabel:process_long {
        time   = { 20.h  * task.attempt }
    }
    withLabel:process_high_memory {
        memory = { 200.GB * task.attempt }
    }
    withLabel:error_ignore {
        errorStrategy = 'ignore'
    }
    withLabel:error_retry {
        errorStrategy = 'retry'
        maxRetries    = 2
    }
    withLabel: process_gpu {
        ext.use_gpu = { workflow.profile.contains('gpu') }
        accelerator = { workflow.profile.contains('gpu') ? 1 : null }
    }
}