curationpretext/modules/local/find/telomere_windows/main.nf at fb314b880b13f9994c42ae6fc4d9472de735a557 · sanger-tol/curationpretext · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
process FIND_TELOMERE_WINDOWS {
    tag "${meta.id}"
    label 'process_low'

    conda "bioconda::java-jdk=8.0.112"
    container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
        'https://depot.galaxyproject.org/singularity/java-jdk:8.0.112--1' :
        'biocontainers/java-jdk:8.0.112--1' }"

    input:
    tuple val(meta), path(file)

    output:
    tuple val( meta ), file( "*.windows" ) , emit: windows
    path "versions.yml"                    , emit: versions

    when:
    task.ext.when == null || task.ext.when

    script:
    def prefix = task.ext.prefix ?: "${meta.id}"
    def VERSION = "1.0" // WARN: Version information not provided by tool on CLI. Please update this string when bumping container versions.
    def telomere_jar = task.ext.telomere_jar ?: ''
    def telomere_jvm_params = task.ext.telomere_jvm_params ?: ''
    def telomere_window_cut = task.ext.telomere_window_cut ?: "99.9"
    """
    java ${telomere_jvm_params} -cp ${projectDir}/bin/${telomere_jar} FindTelomereWindows $file $telomere_window_cut > ${prefix}.windows

    cat <<-END_VERSIONS > versions.yml
    "${task.process}":
        telomere: $VERSION
    END_VERSIONS
    """

    stub:
    def prefix = task.ext.prefix ?: "${meta.id}"
    def VERSION = "1.0" // WARN: Version information not provided by tool on CLI. Please update this string when bumping container versions.
    """
    touch ${prefix}.windows

    cat <<-END_VERSIONS > versions.yml
    "${task.process}":
        telomere: $VERSION
    END_VERSIONS
    """

}