nix: package the CLI as a flake

Expose packages.default via buildGoModule so the binary can be installed
with nix (`nix run github:sanketsudake/chrome-cdp-cli`) instead of only
through the Homebrew cask.

The build mirrors .goreleaser.yaml: subPackages cmd/chrome-cdp,
CGO_ENABLED=0 and the same internal/cli.Version ldflag. The `version`
string in flake.nix has to be bumped with each release tag, since a flake
building `src = self` has no tag to read.

Author: sanketsudake

.gitignore

@@ -22,3 +22,6 @@
 # npm installer shim: downloaded binary + local test deps
 /npm/bin/.bin/
 /npm/node_modules/
+
+# nix build output
+/result

flake.lock

@@ -0,0 +1,53 @@
+{
+  description = "Drive your already-running local Chrome from the command line over CDP";
+
+  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+
+  outputs =
+    { self, nixpkgs }:
+    let
+      # Keep in step with the release tag; goreleaser stamps the same string
+      # into internal/cli from {{ .Version }}.
+      version = "0.3.2";
+
+      systems = [
+        "aarch64-darwin"
+        "x86_64-darwin"
+        "aarch64-linux"
+        "x86_64-linux"
+      ];
+      forAllSystems = f: nixpkgs.lib.genAttrs systems (system: f nixpkgs.legacyPackages.${system});
+    in
+    {
+      packages = forAllSystems (pkgs: rec {
+        chrome-cdp = pkgs.buildGoModule {
+          pname = "chrome-cdp";
+          inherit version;
+          src = self;
+
+          vendorHash = "sha256-8f/eoBJZxQHsiUpUbbbw9NWiduRT+NCEEu90HVWN9vE=";
+
+          subPackages = [ "cmd/chrome-cdp" ];
+
+          # Matches the goreleaser build: pure Go, no cgo.
+          env.CGO_ENABLED = 0;
+
+          ldflags = [
+            "-s"
+            "-w"
+            "-X github.com/sanketsudake/chrome-cdp-cli/internal/cli.Version=${version}"
+          ];
+
+          meta = {
+            description = "Drive your already-running local Chrome from the command line over CDP";
+            homepage = "https://github.com/sanketsudake/chrome-cdp-cli";
+            license = pkgs.lib.licenses.mit;
+            mainProgram = "chrome-cdp";
+          };
+        };
+        default = chrome-cdp;
+      });
+
+      formatter = forAllSystems (pkgs: pkgs.nixfmt-rfc-style);
+    };
+}