kotlin-dsv/build.gradle.kts at main · sargunv/kotlin-dsv · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
import kotlinx.kover.gradle.plugin.dsl.GroupingEntityType
import ru.vyarus.gradle.plugin.mkdocs.task.MkdocsTask

plugins {
  id("org.jetbrains.kotlinx.kover")
  id("org.jetbrains.dokka")
  id("semver")
  id("ru.vyarus.mkdocs-build")
}

dokka {
  moduleName = "kotlin-dsv"
  dokkaPublications { html { outputDirectory = rootDir.absoluteFile.resolve("docs/api") } }
  pluginsConfiguration { html { footerMessage = "Copyright &copy; 2025 Sargun Vohra" } }
}

mkdocs {
  sourcesDir = "."
  strict = true
  publish {
    docPath = null // single version site
  }
}

tasks.withType<MkdocsTask>().configureEach {
  dependsOn("dokkaGenerateHtml")
  extras.assign(provider { mapOf("project_version" to project.version.toString()) })
}

kover {
  reports {
    total {
      log {
        // default groups by module
        groupBy = GroupingEntityType.PACKAGE
      }
    }
  }
}

dependencies {
  dokka(project(":kotlin-dsv"))
  kover(project(":kotlin-dsv"))
}