kotlin-dsv/justfile at main · sargunv/kotlin-dsv · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
#!/usr/bin/env just --justfile

set windows-shell := ["powershell.exe", "-c"]

_default:
    @just --list

pre-commit-install:
    pre-commit install

pre-commit-uninstall:
    pre-commit uninstall

detekt:
    ./gradlew detekt

format:
    pre-commit run --all-files --hook-stage manual || true

test-jvm:
    ./gradlew jvmTest

test-js:
    ./gradlew jsNodeTest

test-wasm:
    ./gradlew wasmJsNodeTest

native_test_task := if os() == "macos" {
    if arch() == "aarch64" { "macosArm64Test" }
    else { "macosX64Test" }
} else if os() == "linux" {
    if arch() == "aarch64" { "linuxArm64Test" }
    else { "linuxX64Test" }
} else if os() == "windows" {
    "mingwX64Test"
} else {
    error("Unsupported platform: {{os()}}-{{arch()}}")
}

test-native:
    ./gradlew {{native_test_task}}

test: test-jvm test-js test-wasm test-native

build:
    ./gradlew build

benchmark:
    ./gradlew benchmark

coverage:
    ./gradlew :koverHtmlReport

build-dokka:
    ./gradlew :dokkaGenerateHtml

build-docs:
    ./gradlew :mkdocsBuild

serve-docs:
    ./gradlew :mkdocsServe