argon2-jvm/build.gradle at master · sbahloul/argon2-jvm · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
plugins {
    id "org.sonarqube" version "2.6"
}

apply plugin: 'org.sonarqube'
apply plugin: 'java'
apply plugin: 'signing'
apply plugin: 'maven'
apply plugin: 'jacoco'

group 'de.mkammerer'
version '2.4'

description 'Argon2 Binding for the JVM'

sourceCompatibility = 1.6
targetCompatibility = 1.6
compileJava.options.encoding = 'UTF-8'
tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

repositories {
    mavenCentral()
}

dependencies {
    compile 'net.java.dev.jna:jna:4.5.0'
    testCompile group: 'junit', name: 'junit', version: '4.12'
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allJava
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

task noLibsJar(type: Jar, dependsOn: javadoc) {
    baseName = project.name + '-nolibs'
    from sourceSets.main.output.classesDirs

    manifest {
        attributes('Automatic-Module-Name': 'de.mkammerer.argon2')
    }
}

task noLibsSourcesJar(type: Jar, dependsOn: classes) {
    baseName = project.name + '-nolibs'
    classifier = 'sources'
    from sourceSets.main.allJava
}

task noLibsJavadocJar(type: Jar, dependsOn: javadoc) {
    baseName = project.name + '-nolibs'
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives sourcesJar
    archives javadocJar
    archives noLibsJar
    archives noLibsSourcesJar
    archives noLibsJavadocJar
}

jar {
    manifest {
        attributes('Automatic-Module-Name': 'de.mkammerer.argon2')
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '4.4.1'
}

signing {
    sign configurations.archives
    required { gradle.taskGraph.hasTask("uploadArchives") }
}

uploadArchives {
    repositories {
        mavenDeployer {
            repository(url: 'https://oss.sonatype.org/service/local/staging/deploy/maven2') {
                authentication(userName: project.properties['sonatype.username'], password: project.properties['sonatype.password'])
            }
            snapshotRepository(url: 'https://oss.sonatype.org/content/repositories/snapshots') {
                authentication(userName: project.properties['sonatype.username'], password: project.properties['sonatype.password'])
            }
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
            // default: With included pre-compiled Argon2 libraries
            addFilter('default') { artifact, file ->
                !file.getName().contains('-nolibs')
            }
            // nolibs: Without included pre-compiled Argon2 libraries
            addFilter('nolibs') { artifact, file ->
                file.getName().contains('-nolibs')
            }

            enhancePom(pom('default'))

            // Publish the nolibs version under a different artifact name
            pom('nolibs').artifactId = 'argon2-jvm-nolibs'
            enhancePom(pom('nolibs'))
        }
    }
}

/**
 * Adds license, developer and SCM tags to the POM file.
 * @param pom POM.
 */
void enhancePom(MavenPom pom) {
    pom.project {
        url 'https://github.com/phxql/argon2-jvm'
        name 'Argon2 JVM'
        description 'Argon2 Binding for the JVM'
        licenses {
            license {
                name 'GNU Lesser General Public License, Version 3'
                url 'https://www.gnu.org/licenses/lgpl-3.0.en.html'
            }
        }
        developers {
            developer {
                name 'Moritz Kammerer'
                email 'kammerer.moritz@gmail.com'
                url 'https://www.mkammerer.de/'
            }
        }
        scm {
            connection 'scm:git:git://github.com/phxql/argon2-jvm.git'
            developerConnection 'scm:git:git://github.com/phxql/argon2-jvm.git'
            url 'https://github.com/phxql/argon2-jvm'
        }
    }
}

sonarqube {
    properties {
        property "sonar.exclusions", "src/main/java/de/mkammerer/argon2/jna/*.java"
    }
}