What's wrong with my script?

[hairui]

I wrote a script to convert time description to seconds number. which like :

  1 #class rgt kill;
  2 #class rgt open;
  3
  4 #function time_2_seconds {
  5         #regexp {%1} {You can get the job right now.} {
  6                 #showme {Right NOW};
  7                 #return 0;
  8         }
  9         {
 10                 #regexp {%1} {You can get the job %%+ minute(s) %%+ seconds later.} {
 11                         #showme &1 and &2;
 12                         #local time_remain 0;
 13                         #math time_remain {&1 * 60 + &2};
 14                         #showme {time_remain: $time_remain};
 15                         #return {$time_remain};
 16                 }
 17                 {
 18                         #regexp {%1} {You can get the job %%+ second(s) later.} {
 19                                 #showme {&1 seconds.}
 20                                 #local time_remain 0;
 21                                 #math time_remain {&1};
 22                                 #return {$time_remain};
 23                         }
 24                         {
 25                                 #return -1;
 26                         };
 27                 };
 28         };
 29 };
 30
 31 #class rgt close;

• Firstly I test the situation of zero.

#showme @time_2_seconds{You can get the job right now.}
#DEBUG FUNCTION {time_2_seconds}
    #regexp {You can get the job right now.} {You can get the job right now.}
Right NOW
    #else
    #endregex
#DEBUG FUNCTION: (result) (0) [48]
0

Things seemed all ok.

• Then I tested the situation remain time more than 1 minute.

#showme @time_2_seconds{You can get the job 1 minute(s) 56 seconds later.}
#DEBUG FUNCTION {time_2_seconds}
    #regexp {You can get the job 1 minute(s) 56 seconds later.} {You can get the job right now.}
    #else
        #regexp {You can get the job 1 minute(s) 56 seconds later.} {You can get the job %+ minute(s) %+ seconds later.}
1 and 56
time_remain: 116
        #else
        #endregex
    #endregex
#DEBUG FUNCTION: (result) (0) [48]
0

This time I can see the script calculate the time and try to return it. But the function returns a value 0.

• Finally I tested the last situation.

#showme @time_2_seconds{You can get the job 33 second(s) later.}
#DEBUG FUNCTION {time_2_seconds}
    #regexp {You can get the job 33 second(s) later.} {You can get the job right now.}
    #else
        #regexp {You can get the job 33 second(s) later.} {You can get the job %+ minute(s) %+ seconds later.}
        #else
            #regexp {You can get the job 33 second(s) later.} {You can get the job %+ second(s) later.}
            #else
            #endregex
        #endregex
    #endregex
#DEBUG FUNCTION: (result) (0) [48]
0

33 seconds.

Again I can see the output of expected 33 seconds. But the return value is 0 again.

I was so puzzled. Why can't I get the result value as expected?

~ ~

[scandum]

The problem is with the way #regex works, which causes problems with #local and #return. Your code would work with #if and #else, but #regex has its own scope. The following ought to work:

#class rgt kill;
#class rgt open;

#function time_2_seconds {
        #var time_remain 0;
        #regexp {%1} {You can get the job right now.} {
                #showme {Right NOW};
        }
        {
                #regexp {%1} {You can get the job %%+ minute(s) %%+ seconds later.} {
                        #showme &1 and &2;
                        #math time_remain {&1 * 60 + &2};
                        #showme {time_remain: $time_remain};
                }
                {
                        #regexp {%1} {You can get the job %%+ second(s) later.} {
                                #showme {&1 seconds.}
                                #math time_remain {&1};
                        }
                        {
                                #math time_remain -1;
                        };
                };
        };
        #return {$time_remain};
};

#class rgt close;

[hairui]

Thanks. It works well.
So there are some limits for #regexp and #local.