Remove duplication by introducing checkstyle-conventions plugin

Author: marcphilipp

gradle/plugins/common/src/main/kotlin/junitbuild.checkstyle-conventions.gradle.kts

@@ -0,0 +1,13 @@
+plugins {
+	base
+	checkstyle
+}
+
+checkstyle {
+	toolVersion = requiredVersionFromLibs("checkstyle")
+	configDirectory = rootProject.layout.projectDirectory.dir("gradle/config/checkstyle")
+}
+
+tasks.check {
+	dependsOn(tasks.withType<Checkstyle>())
+}

gradle/plugins/common/src/main/kotlin/junitbuild.checkstyle-nohttp.gradle.kts

@@ -1,35 +1,24 @@
 plugins {
-	base
-	checkstyle
-}
-
-checkstyle {
-	toolVersion = requiredVersionFromLibs("checkstyle")
-	configDirectory = rootProject.layout.projectDirectory.dir("gradle/config/checkstyle")
+	id("junitbuild.checkstyle-conventions")
 }
 
 dependencies {
 	checkstyle(dependencyFromLibs("nohttp-checkstyle"))
 }
 
-tasks {
-	val checkstyleNohttp by registering(Checkstyle::class) {
-		group = "verification"
-		description = "Checks for illegal uses of http://"
-		classpath = files(configurations.checkstyle)
-		config = resources.text.fromFile(checkstyle.configDirectory.file("checkstyleNohttp.xml"))
-		source = fileTree(layout.projectDirectory) {
-			exclude(".git/**", "**/.gradle/**")
-			exclude(".idea/**", ".eclipse/**")
-			exclude("**/*.class")
-			exclude("**/*.hprof")
-			exclude("**/*.jar")
-			exclude("**/*.jpg", "**/*.png")
-			exclude("**/*.jks")
-			exclude("**/build/**")
-		}
-	}
-	check {
-		dependsOn(checkstyleNohttp)
+tasks.register<Checkstyle>("checkstyleNohttp") {
+	group = "verification"
+	description = "Checks for illegal uses of http://"
+	classpath = files(configurations.checkstyle)
+	config = resources.text.fromFile(checkstyle.configDirectory.file("checkstyleNohttp.xml"))
+	source = fileTree(layout.projectDirectory) {
+		exclude(".git/**", "**/.gradle/**")
+		exclude(".idea/**", ".eclipse/**")
+		exclude("**/*.class")
+		exclude("**/*.hprof")
+		exclude("**/*.jar")
+		exclude("**/*.jpg", "**/*.png")
+		exclude("**/*.jks")
+		exclude("**/build/**")
 	}
 }

gradle/plugins/common/src/main/kotlin/junitbuild.java-library-conventions.gradle.kts

@@ -10,9 +10,9 @@ plugins {
 	`java-library`
 	eclipse
 	idea
-	checkstyle
 	id("junitbuild.base-conventions")
 	id("junitbuild.build-parameters")
+	id("junitbuild.checkstyle-conventions")
 	id("junitbuild.jacoco-java-conventions")
 }