build: Add options to select sanitizers in configure.py

We are going to add ThreadSanitizer that can't be used together with
AddressSanitizer. We want to choose which sanitizers to use.

Sanitizers can be specified as semicolon separated list:
./configure.py --sanitizers address;undefined_behavior

Specified sanitizers are passed to Seastar_SANITIZERS list.

Enabling sanitizers is consistently with Seastar_SANITIZE option.

Author: devDDen

CMakeLists.txt

@@ -356,7 +356,13 @@ set (Seastar_SANITIZE
   "DEFAULT"
   CACHE
   STRING
-  "Enable ASAN and UBSAN. Can be ON, OFF or DEFAULT (which enables it for Debug and Sanitize)")
+  "Enable sanitizers. Can be ON, OFF or DEFAULT (which enables it for Debug and Sanitize)")
+
+set (Seastar_SANITIZERS
+  "address;undefined_behavior"
+  CACHE
+  STRING
+  "Sanitizers enabled when building Seastar")
 
 set (Seastar_DEBUG_SHARED_PTR
   "DEFAULT"
@@ -372,10 +378,30 @@ set (Seastar_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 set (Seastar_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 set (Seastar_GEN_BINARY_DIR ${Seastar_BINARY_DIR}/gen)
 
+include (TriStateOption)
+tri_state_option (${Seastar_SANITIZE}
+  DEFAULT_BUILD_TYPES "Debug" "Sanitize"
+  CONDITION sanitizers_enabled)
+
+if (NOT sanitizers_enabled)
+  set (Seastar_SANITIZERS "")
+endif ()
+
 #
 # Dependencies.
 #
 
+if (NOT Seastar_SANITIZE)
+  # Sanitizers are disabled for all build modes
+  set (Seastar_SANITIZERS_COMPONENTS)
+elseif (Seastar_SANITIZE STREQUAL "ON")
+  # Sanitizers are enabled for all build modes
+  set (Seastar_SANITIZERS_COMPONENTS ${Seastar_SANITIZERS})
+elseif (CMAKE_BUILD_TYPE MATCHES "Debug|Sanitize")
+  # Sanitizers are enabled only for preconfigured modes
+  set (Seastar_SANITIZERS_COMPONENTS ${Seastar_SANITIZERS})
+endif ()
+
 include (SeastarDependencies)
 seastar_find_dependencies ()
 
@@ -863,19 +889,16 @@ if (Seastar_DPDK)
       DPDK::dpdk)
 endif ()
 
-include (TriStateOption)
-tri_state_option (${Seastar_SANITIZE}
-  DEFAULT_BUILD_TYPES "Debug" "Sanitize"
-  CONDITION condition)
-if (condition)
+if (sanitizers_enabled)
   if (NOT Sanitizers_FOUND)
     message (FATAL_ERROR "Sanitizers not found!")
   endif ()
-  set (Seastar_Sanitizers_OPTIONS $<${condition}:${Sanitizers_COMPILE_OPTIONS}>)
-  target_link_libraries (seastar
-    PUBLIC
-      $<${condition}:Sanitizers::address>
-      $<${condition}:Sanitizers::undefined_behavior>)
+  set (Seastar_Sanitizers_OPTIONS $<${sanitizers_enabled}:${Sanitizers_COMPILE_OPTIONS}>)
+  foreach (component ${Seastar_SANITIZERS})
+    target_link_libraries (seastar
+      PUBLIC
+        $<${sanitizers_enabled}:Sanitizers::${component}>)
+  endforeach ()
 endif ()
 
 # We only need valgrind to find uninitialized memory uses, so disable

cmake/SeastarConfig.cmake.in

@@ -56,6 +56,8 @@ include (SeastarDependencies)
 set (Seastar_DPDK @Seastar_DPDK@)
 set (Seastar_IO_URING @Seastar_IO_URING@)
 set (Seastar_HWLOC @Seastar_HWLOC@)
+set (Seastar_SANITIZERS_COMPONENTS @Seastar_SANITIZERS_COMPONENTS@)
+
 seastar_find_dependencies ()
 
 if (NOT TARGET Seastar::seastar)

cmake/SeastarDependencies.cmake

@@ -93,7 +93,11 @@ macro (seastar_find_dependencies)
     seastar_find_dep (LibUring 2.0 REQUIRED)
   endif()
   seastar_find_dep (LinuxMembarrier)
-  seastar_find_dep (Sanitizers)
+  if (Seastar_SANITIZERS_COMPONENTS)
+    seastar_find_dep (Sanitizers
+      COMPONENTS
+        ${Seastar_SANITIZERS_COMPONENTS})
+  endif ()
   seastar_find_dep (SourceLocation)
   seastar_find_dep (StdAtomic REQUIRED)
   seastar_find_dep (SystemTap-SDT)

configure.py

@@ -142,6 +142,7 @@ def standard_supported(standard, compiler='g++'):
 arg_parser.add_argument('--dpdk-machine', default='native', help='Specify the target architecture')
 add_tristate(arg_parser, name='deferred-action-require-noexcept', dest='deferred_action_require_noexcept', help='noexcept requirement for deferred actions', default=True)
 arg_parser.add_argument('--prefix', dest='install_prefix', default='/usr/local', help='Root installation path of Seastar files')
+arg_parser.add_argument('--sanitizers', action='store', dest='sanitizers', default='address;undefined_behavior', help='Use specified sanitizers')
 args = arg_parser.parse_args()
 
 
@@ -209,6 +210,7 @@ def configure_mode(mode):
         tr(args.deferred_action_require_noexcept, 'DEFERRED_ACTION_REQUIRE_NOEXCEPT'),
         tr(args.unused_result_error, 'UNUSED_RESULT_ERROR'),
         tr(args.debug_shared_ptr, 'DEBUG_SHARED_PTR', value_when_none='default'),
+        tr(args.sanitizers, 'SANITIZERS'),
     ]
 
     ingredients_to_cook = set(args.cook)