chore(nix): add flake

chore(nix): add flake

Author: cmdoret

.envrc

@@ -0,0 +1 @@
+use flake ./tools/nix --no-pure-eval

.github/workflows/build-nix-shell.yaml

@@ -0,0 +1,13 @@
+on:
+  pull_request_target:
+    paths:
+      - '**.nix'
+steps:
+  - uses: actions/checkout@v3
+  - name: Install Nix
+    uses: cachix/install-nix-action@v17
+    with:
+      extra_nix_config: |
+        access-tokens = github.com=${{ secrets.GITHUB_TOKEN }}
+  - name: Build dev shell
+    run: nix develop --no-pure-eval --accept-flake-config "./tools/nix" --command "bash"

.gitignore

@@ -1,3 +1,6 @@
+# nix
+.devenv/
+.direnv/
 # project
 .idea/
 .vscode/

README.md

@@ -6,9 +6,15 @@ Langchain-powered natural language interface to RDF knowledge-graphs.
 This repository uses `uv` for package management. A Makefile rule is provided to install the dependencies:
 
 ```bash
-make install
+just setup
 ```
 
+To start the nix-based development shell (linux-only), run:
+
+```bash
+just dev
+``````
+
 ## Configuration
 
 Configuration variables are loaded from the `.env` file or environment variables. A template configuration file is provided in `.env.example`.

justfile

@@ -0,0 +1,43 @@
+set positional-arguments
+set dotenv-load
+set shell := ["bash", "-cue"]
+root_dir := `git rev-parse --show-toplevel`
+flake_dir := root_dir / "tools/nix"
+
+# Manage nix flakes
+mod nix 'tools/just/nix.just'
+
+[private]
+default:
+  just --unsorted --list --no-aliases
+
+alias dev := develop
+
+# Enter a development shell.
+develop:
+  just nix::develop default
+
+# Set up python environment.
+setup:
+  @echo "🔧 Setting up python environment"
+  uv sync --all-extras --group dev
+  uv run pre-commit install
+
+
+# Run all quality checks.
+check: setup
+  @echo "🚀 Validating lock file"
+  uv lock --check
+  @echo "🚀 Running all pre-commit hooks"
+  uv run pre-commit run -a
+
+alias fmt := format
+# Format code.
+format *args: setup
+  @echo "🚀 Formatting python code"
+  uv run ruff format {{args}}
+
+# Run unit tests.
+test *args: setup
+  @echo "🚀 Testing code: Running pytest"
+  @uv run pytest {{args}}

tools/just/nix.just

@@ -0,0 +1,22 @@
+set positional-arguments
+set dotenv-load
+set shell := ["bash", "-cue"]
+root_dir := `git rev-parse --show-toplevel`
+flake_dir := root_dir / "tools/nix"
+
+## Nix Stuff ==================================================================
+# Show all packages configured in the Nix `flake.nix`.
+list *args:
+    cd {{flake_dir}} && nix flake --no-pure-eval show
+
+# Enter the Nix `devShell` with name `$1` and execute the command `${@:2}` (default command is '$SHELL')
+[private]
+develop *args:
+    #!/usr/bin/env bash
+    set -eu
+    shell="$1"; shift 1;
+    args=("$@") && [ "${#args[@]}" != 0 ] || args="$SHELL"
+    cd {{root_dir}}
+    nix develop --no-pure-eval --accept-flake-config \
+        "{{flake_dir}}#$shell" --command "${args[@]}"
+## ============================================================================