.zshrc

typeset -U path fpath

path=(
  "$HOME/bin"
  "$HOME/.local/bin"
  "$HOME/.local/npm/bin"
  "$HOME/go/bin"
  "$HOME/.cargo/bin"
  "$HOME/.bun/bin"
  /opt/homebrew/bin
  $path
)

fpath=("$HOME/.zsh/plugins/zsh-completions/src" $fpath)
autoload -Uz compinit && compinit

for plugin in \
  "$HOME/.zsh/plugins/zsh-autosuggestions/zsh-autosuggestions.zsh" \
  "$HOME/.zsh/plugins/zsh-history-substring-search/zsh-history-substring-search.zsh" \
  "$HOME/.zsh/plugins/fast-syntax-highlighting/fast-syntax-highlighting.plugin.zsh"; do
  [[ -r "$plugin" ]] && source "$plugin"
done

zstyle ':completion:*' menu select
zstyle ':completion:*' matcher-list '' 'm:{a-zA-Z}={A-Za-z}' 'r:|[._-]=* r:|=*' 'l:|=* r:|=*'
zstyle ':completion:*' insert-tab pending
zstyle ':completion:*' completer _expand _complete _files _correct _approximate

bindkey '^[[A' history-substring-search-up
bindkey '^[[B' history-substring-search-down

HISTFILE=${ZDOTDIR:-$HOME}/.zsh_history
SAVEHIST=50000
HISTSIZE=20000

setopt NO_CASE_GLOB
setopt GLOB_COMPLETE
setopt EXTENDED_HISTORY
setopt APPEND_HISTORY
setopt INC_APPEND_HISTORY
setopt HIST_VERIFY
setopt HIST_IGNORE_SPACE
setopt HIST_IGNORE_DUPS
setopt HIST_SAVE_NO_DUPS
setopt HIST_FIND_NO_DUPS
setopt HIST_REDUCE_BLANKS

export NVM_DIR="$HOME/.nvm"
[ -s "$NVM_DIR/nvm.sh" ] && \. "$NVM_DIR/nvm.sh"  # This loads nvm
[ -s "$NVM_DIR/bash_completion" ] && \. "$NVM_DIR/bash_completion"  # This loads nvm bash_completion

export PATH="$HOME/.local/bin:$PATH"

[[ -s "$HOME/.gvm/scripts/gvm" ]] && source "$HOME/.gvm/scripts/gvm"
[[ -n "${GOROOT:-}" && -x "$GOROOT/bin/go" ]] && path=("$GOROOT/bin" $path)

[[ -r "$HOME/.amazon.env" ]] && source "$HOME/.amazon.env"

if command -v starship >/dev/null 2>&1; then
  eval "$(starship init zsh)"
fi

for file in "$HOME/.kubectl.aliases" "$HOME/.amazon.aliases"; do
  [[ -r "$file" ]] && source "$file"
done