qputty-qt5/linkHack.pri at master · seppd/qputty-qt5 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# hack so that putty can be linked
isEmpty(OBJECTS_DIR) {
    win32 {
        CONFIG(debug,debug|release) {
            OBJECTS_DIR=debug
        }
        CONFIG(release,debug|release) {
            OBJECTS_DIR=release
        }
    } else {
        OBJECTS_DIR=.
    }
}

TARGETS=$$OBJECTS_DIR/sbcsdat$$QMAKE_EXT_OBJ
!contains(TEMPLATE,vcapp) {
    TARGETS+=$$OBJECTS_DIR/utf8$$QMAKE_EXT_OBJ
}

win32 {
    OBJECTS_DIR=($$replace(OBJECTS_DIR,/,\))
    TARGETS=($$replace(TARGETS,/,\))
}

QMAKE_EXTRA_TARGETS*=$$TARGETS
PRE_TARGETDEPS*=$$TARGETS
QMAKE_LFLAGS*=$$TARGETS
QMAKE_CLEAN*=$$TARGETS

sbcsdat_o_dep=$$PUTTY_HOME/charset/sbcsdat.c $$PUTTY_HOME/charset/charset.h $$PUTTY_HOME/charset/internal.h

win32 {
    $$OBJECTS_DIR\sbcsdat.obj.depends=$$sbcsdat_o_dep
} else {
    $$OBJECTS_DIR/sbcsdat.o.depends=$$sbcsdat_o_dep
    $$OBJECTS_DIR/sbcsdat.o.commands=$(CC) -c $(CFLAGS) $(INCPATH) -o $$OBJECTS_DIR/sbcsdat$$QMAKE_EXT_OBJ $$PUTTY_HOME/charset/sbcsdat.c
}


utf8_o_dep=$$PUTTY_HOME/charset/utf8.c $$PUTTY_HOME/charset/charset.h $$PUTTY_HOME/charset/internal.h

win32 {
    $$OBJECTS_DIR\utf8.obj.depends=$$utf8_o_dep
} else {
    $$OBJECTS_DIR/utf8.o.depends=$$utf8_o_dep
    $$OBJECTS_DIR/utf8.o.commands=$(CC) -c $(CFLAGS) $(INCPATH) -o $$OBJECTS_DIR/utf8$$QMAKE_EXT_OBJ $$PUTTY_HOME/charset/utf8.c
}