discord4j-framework/build.gradle.kts at master · simplified-dev/discord4j-framework · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
plugins {
    id("java-library")
    id("application")
}

group = "dev.sbs"
version = "0.1.0"

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(21))
    }
}

repositories {
    mavenCentral()
    maven(url = "https://central.sonatype.com/repository/maven-snapshots")
    maven(url = "https://jitpack.io")
}

dependencies {
    // Lombok Annotations
    compileOnly(libs.lombok)
    annotationProcessor(libs.lombok)
    testCompileOnly(libs.lombok)
    testAnnotationProcessor(libs.lombok)

    // Tests
    testImplementation(libs.hamcrest)
    testImplementation(libs.junit.jupiter.api)
    testRuntimeOnly(libs.junit.jupiter.engine)
    testImplementation(libs.junit.platform.launcher)

    // https://central.sonatype.com/artifact/com.discord4j/discord4j-core/versions
    api(libs.discord4j)

    // Simplified Libraries (extracted to github.com/simplified-dev)
    api("com.github.simplified-dev:collections") { version { strictly("2f2aa58") } }
    api("com.github.simplified-dev:utils") { version { strictly("a2f3ccd") } }
    api("com.github.simplified-dev:reflection") { version { strictly("c02511a") } }
    api("com.github.simplified-dev:scheduler") { version { strictly("f9b1bd4") } }
    api("com.github.simplified-dev:yaml") { version { strictly("586bc52") } }
    api("com.github.simplified-dev:client") { version { strictly("64ae978") } }
    api("com.github.simplified-dev:dataflow") { version { strictly("9e5906d") } }

    implementation(libs.sentry)
}

tasks {
    test {
        useJUnitPlatform()
    }

    register<JavaExec>("generateDiagrams") {
        description = "Generates SVG hierarchy diagrams for context and component packages"
        group = "documentation"
        mainClass.set("dev.sbs.discordapi.diagram.DiagramGenerator")
        classpath = sourceSets["test"].runtimeClasspath
    }
}