spring-framework/build.gradle.kts at master · simplified-dev/spring-framework · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
plugins {
    id("java-library")
}

group = "dev.sbs"
version = "0.1.0"

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(21))
    }
}

repositories {
    mavenCentral()
    maven(url = "https://central.sonatype.com/repository/maven-snapshots")
    maven(url = "https://jitpack.io")
}

dependencies {
    // Simplified Annotations
    annotationProcessor(libs.simplified.annotations)

    // Lombok Annotations
    compileOnly(libs.lombok)
    annotationProcessor(libs.lombok)
    testCompileOnly(libs.lombok)
    testAnnotationProcessor(libs.lombok)

    // SpringDoc OpenAPI (compile-only for optional documentation enrichment)
    compileOnly(libs.springdoc.openapi.common)

    // Tests
    testImplementation(libs.springdoc.openapi.scalar)
    testImplementation(libs.hamcrest)
    testImplementation(libs.junit.jupiter.api)
    testRuntimeOnly(libs.junit.jupiter.engine)
    testImplementation(libs.junit.platform.launcher)
    testImplementation(libs.spring.boot.test)
    testRuntimeOnly(libs.spring.boot.properties.migrator)

    // Exported dependencies (available to consumers)
    api("com.github.simplified-dev:gson-extras") { version { strictly("b68510e") } }
    api("com.github.simplified-dev:client") { version { strictly("64ae978") } }
    api(libs.gson)
    api(libs.spring.boot.actuator)
    api(libs.spring.boot.web)
    api(libs.spring.boot.security)
    api(libs.bucket4j.core)
}

tasks {
    test {
        useJUnitPlatform()
        // Forward the auth-enabled property so users can run
        // `./gradlew :server-api:test -Dapi.key.authentication.enabled=false`
        // to exercise the auth-disabled path. Rate-limit tests self-skip via
        // JUnit Assumptions when the property is false.
        systemProperty("api.key.authentication.enabled",
            providers.systemProperty("api.key.authentication.enabled").orElse("true").get())
    }
}