build.gradle

buildscript {
    ext.repos = {
        google()
        mavenCentral()
    }

    repositories repos
    dependencies {
        classpath 'com.android.tools.build:gradle:8.13.1'
    }
}

ext {
    junitVersion = '4.13.2'
    baristaVersion = '4.3.0'
    androidxEspressoVersion = '3.5.0'
    androidxTestRulesVersion = '1.4.0'
    androidxTestUiAutomatorVersion = '2.2.0'
    androidxTestExtJunitVersion = '1.1.4'
    mockitoVersion = '4.9.0'
    byteBuddyVersion = '1.18.1'

}

def buildProjects() {
    subprojects.findAll { new File(it.projectDir, 'build.gradle').file }
}

def androidApplicationProjects() {
    subprojects.findAll { it.name.endsWith("app")}
}

def androidLibraryProjects() {
    buildProjects().findAll {  !androidApplicationProjects().contains(it)}
}

configure(androidLibraryProjects()) {
    apply plugin: 'com.android.library'
}

configure(androidApplicationProjects()) {
    apply plugin: 'com.android.application'
}


configure(buildProjects()) {
    repositories repos

    android {

        compileSdkVersion 33

        defaultConfig {
            minSdkVersion 19
            targetSdkVersion 33
        }

        testOptions {
            unitTests {
                returnDefaultValues = true
            }
        }

        buildTypes {
            release {
                minifyEnabled false
                proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
            }
        }


        compileOptions {
            sourceCompatibility JavaVersion.VERSION_11
            targetCompatibility JavaVersion.VERSION_11
        }

        lintOptions {
            abortOnError false
        }
    }


}

task clean(type: Delete) {
    delete rootProject.buildDir
}