How do I configure the backend? Error initializing winit event loop

[WhiteBlackGoose]

Hi.

I cloned the template, replaced placeholders and ran cargo run

Error: Other("Could not initialize backend.\nError from Winit backend: Error initializing winit event loop: os error at /home/goose/.cargo/registry/src/index.crates.io-6f17d22bba15001f/winit-0.29.4/src/platform_impl/linux/wayland/event_loop/mod.rs:81: The wayland library could not be loaded\nNo backends configured.")

I'm on NixOS + Wayland (hyprland).

How to configure the backend? (tried SLINT_BACKEND=winit but same result)

[tronical]

Slint will dynamically open the wayland libraries, it will try to open libwayland-client.so.0 or libwayland-client.so. Are those accessible in your Nix environment?

[WhiteBlackGoose]

@jasper-at-windswept as an attribute of your shell. E. g. devShells.default.LD_LIBRARY_PATH = .... If you want globally, look into system environmental variables for nixos.

[jasper-clarke]

Thanks!

[gordug]

Are there any plans for these to be bundles with rust builds, similar to how you can have self-contained apps in.Net?

[ruffsl]

@WhiteBlackGoose , what else would be needed here in order to run the slint examples using opengl?

I can't seem to get the example window to display on wayland using plasma 6 regardless of slint backend:

ruffsl@nixos ~/g/s/s/e/opengl_texture (master) [SIGINT]> RUST_BACKTRACE=1 SLINT_NO_QT=1 SLINT_BACKEND=winit-femtovg cargo run
    Finished `dev` profile [unoptimized + debuginfo] target(s) in 0.59s
     Running `/home/ruffsl/git/slint-ui/slint/target/debug/opengl_texture`
^C⏎

For references, here is the shell.nix I've used to get the example rust template to work:

{ pkgs ? import <nixpkgs> { } }:

let
  libPath = with pkgs; lib.makeLibraryPath [
    fontconfig
    libxkbcommon
    wayland
  ];
in
pkgs.mkShell {
  packages = with pkgs; [
    openssl
    pkg-config
  ];

  LD_LIBRARY_PATH = "$LD_LIBRARY_PATH:${libPath}";
}

• https://github.com/slint-ui/slint-rust-template/tree/8cb5817b2999435408d5e53c637d5ab9f883d003

[ruffsl]

Nevermind. The solution was as simple as adding libGL to the list of library packages in libPath above.

  libPath = with pkgs; lib.makeLibraryPath [
    fontconfig
    libxkbcommon
+    libGL
    wayland
  ];

• https://github.com/dtomvan/nixpkgs/blob/c131f21806d773c2ecb50ce094de7cf1dbca5206/pkgs/by-name/sl/slint-viewer/package.nix#L25

[txtyash]

For fellow nix newbies like me, this is where it goes in my flake.nix:

          devShells.default = mkShell {
            buildInputs = [
              openssl
              pkg-config
              rust-bin.beta.latest.default
            ];
            packages = [ pkgs.bashInteractive ];
            # TODO: Read on shellHooks
            shellHook = ''
              # alias ls=eza
              # alias find=fd
            '';
            LD_LIBRARY_PATH = "$LD_LIBRARY_PATH:${ with pkgs; lib.makeLibraryPath [
                wayland
                libxkbcommon
                fontconfig
            ] }";
          };

[sakshatshinde]

If someone wants to use it with oxalica/rust-overlay

# flake.nix
{
  description = "rust devshell for linpull";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, rust-overlay, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs {
          inherit system overlays;
        };
      in
      {
        devShells.default = with pkgs; mkShell {
          buildInputs = [
            openssl
            pkg-config
            eza
            fd
            rust-bin.beta.latest.default
          ];
          
          LD_LIBRARY_PATH = "$LD_LIBRARY_PATH:${ with pkgs; lib.makeLibraryPath [
		                wayland
		                libxkbcommon
		                fontconfig
		            ] }";

          shellHook = ''
            alias ls=eza
            alias find=fd
          '';
        };
      }
   );
}

Run nix develop in the project root

[mitchty]

A note for xorg/x11, at the least you'll need a few more libraries based off of stracing startup. Of which maybe we could get the libraries searched for in the backtrace?

          LD_LIBRARY_PATH = "$LD_LIBRARY_PATH:${ lib.makeLibraryPath [
            pkgs.xorg.libX11
            pkgs.xorg.libXcursor
            pkgs.xorg.libXi
            pkgs.wayland
            pkgs.libxkbcommon
            pkgs.fontconfig
          ] }";