justfile

set dotenv-load

help:
  @just --list

# Install apps into nix profile, 'just install-nix "foo bar"
install-nix nix_apps args="":
  @for app in {{nix_apps}}; do \
      if !(nix profile list | rg -q -F "\.${app}"); then \
          echo "Installing ${app}"; \
          outputs=$(nix eval nixpkgs#${app}.outputs |sed 's/[]["]//g'); \
          for out in $outputs; do \
              echo "Building output ${out} for ${app}"; \
              nix build {{ args }} nixpkgs#${app}.${out}; \
          done; \
          nix profile install {{ args }} nixpkgs#${app}; \
      else \
          echo "Package ${app} already installed, skipping"; \
      fi \
  done

# Install an app from its own flake (not in nixpkgs), e.g. 'just install-flake
# "github:owner/repo"'. --accept-flake-config trusts the flake's declared cache.
install-flake flake_ref:
  @if nix profile list | rg -q -F "{{flake_ref}}"; then \
      echo "Flake {{flake_ref}} already installed, skipping"; \
  else \
      echo "Installing {{flake_ref}}"; \
      nix profile install --accept-flake-config "{{flake_ref}}"; \
  fi

# Install apps that ship their own flake rather than living in nixpkgs
install-flake-apps:
  @just install-flake "github:modem-dev/hunk"
  @just install-flake "github:agent-of-empires/agent-of-empires"

# Install fun apps
install-fun-apps: (install-nix "boxes cowsay figlet fortune lolcat toilet fastfetch")

# Install apps for every day use
install-system-apps:
  @just install-nix "act"
  @just install-nix "aider-chat"
  @just install-nix "asciinema"
  @just install-nix "asciinema-agg"
  @just install-nix "ast-grep"
  @just install-nix "atuin"
  @just install-nix "azure-cli"
  @just install-nix "bash"
  @just install-nix "bat"
  @just install-nix "bottom"
  @just install-nix "cheat"
  @just install-nix "cmake"
  @just install-nix "cairo"
  @just install-nix "colima"
  @just install-nix "colordiff"
  @just install-nix "coreutils"
  @just install-nix "crane"
  @just install-nix "cue"
  @just install-nix "delta"
  @just install-nix "direnv"
  @just install-nix "docker-client"
  @just install-nix "docker-compose"
  @just install-nix "docker-credential-helpers"
  @just install-nix "docker-ls"
  @just install-nix "duf"
  @just install-nix "dwdiff"
  @just install-nix "earthly"
  @just install-nix "easyrsa"
  @just install-nix "eza"
  @just install-nix "ffmpeg"
  @just install-nix "flock"
  @just install-nix "fontconfig"
  @just install-nix "freetype"
  @just install-nix "fzf"
  @just install-nix "google-cloud-sdk"
  @just install-nix "gettext"
  @just install-nix "gh"
  @just install-nix "git"
  @just install-nix "git-crypt"
  @just install-nix "gnumake"
  @just install-nix "gnupg"
  @just install-nix "graphviz"
  @just install-nix "harfbuzz"
  @just install-nix "heroku"
  @just install-nix "htop"
  @just install-nix "icu"
  @just install-nix "imagemagick"
  @just install-nix "jless"
  @just install-nix "jq"
  @just install-nix "k6"
  @just install-nix "k9s"
  @just install-nix "libgit2"
  @just install-nix "libffi"
  @just install-nix "libpng"
  @just install-nix "tokei"
  @just install-nix "lz4"
  @just install-nix "minikube"
  @just install-nix "mise"
  @just install-nix "ncurses"
  @just install-nix "ngrok" "--impure"
  @just install-nix "openssl"
  @just install-nix "openvpn"
  @just install-nix "pandoc"
  @just install-nix "pango"
  @just install-nix "pdfgrep"
  @just install-nix "pixman"
  @just install-nix "pkg-config"
  @just install-nix "poppler-utils"
  @just install-nix "postgresql.dev"
  @just install-nix "pre-commit"
  @just install-nix "protobuf"
  @just install-nix "pwgen"
  @just install-nix "neovim"
  @just install-nix "readline"
  @just install-nix "ripgrep"
  @just install-nix "sd"
  @just install-nix "shellcheck"
  @just install-nix "starship"
  @just install-nix "stow"
  @just install-nix "terraform-docs"
  @just install-nix "tree"
  @just install-nix "tmux"
  @just install-nix "unzip"
  @just install-nix "util-linux"
  @just install-nix "visidata"
  @just install-nix "watch"
  @just install-nix "watchman"
  @just install-nix "wget"
  @just install-nix "xh"
  @just install-nix "xz"
  @just install-nix "yq-go"
  @just install-nix "zellij"
  @just install-nix "zsh"

# Install apps for doing SRE work
install-sre-apps:
  @just install-nix "argocd awscli2 aws-nuke aws-vault dos2unix krew kubie"
  @just install-nix "kind kubecolor redis sops stern teleport terraformer"
  @just install-nix "qemu helm-docs kafkactl cilium-cli"
  @just install-nix "ssm-session-manager-plugin"
  @just install-nix "mage golangci-lint e1s granted"

# Install all applications
install: install-system-apps install-sre-apps install-fun-apps install-flake-apps
  @echo "Done installing all packages"

# Upgrade all installed applications
nix-upgrade:
  nix profile upgrade '.*' --impure

# Repair the nix store
nix-repair:
  nix-store --repair --verify --check-contents

# Remove packages that aren't referenced
nix-gc:
  nix profile wipe-history
  nix-collect-garbage --delete-old
  nix store gc
  nix store optimise

# Installs all the dotfiles
install-dotfiles:
  cd dotfiles && stow --verbose=1 --target=$HOME */

# Removes all the dotfiles
remove-dotfiles:
  cd dotfiles && stow --verbose=1 --delete --target=$HOME */

# --- Dev VMs (Colima) ----------------------------------------------------
# One Linux VM per project, NAMED AFTER its ~/code subdir, so each VM mounts
# ONLY that project and can't see your other projects or $HOME:
#   `just vm-up drape`     -> profile "drape",    mounts ~/code/drape
#   `just vm-up stacklet`  -> profile "stacklet", mounts ~/code/stacklet
# vz/virtiofs + the no-$HOME default also come from the stowed template
# (~/.config/colima/_templates/default.yaml); the --mount here narrows it to the
# one project (a flag mount replaces the template's broader default).
#
# RAM note: an 18GiB host can't comfortably run two 8GiB VMs at once, so the
# defaults are modest (6 CPU / 6 GiB) to let two coexist. Bump per-invocation
# for a single heavy VM: `just vm-up drape 8 12 150`. Sizing changes apply after
# a down + up. Both disks are thin-provisioned (sparse), so the numbers are
# ceilings, not upfront cost; root_disk sizes /nix (the toolchain), disk sizes
# the container-runtime store.
#
# Usage: vm-up <name> [cpu] [mem] [disk] [root_disk] | vm-down/vm-ssh/vm-status <name> | vm-list
#
# Create or start a project VM (Colima profile), then provision it. Mounts the
# named project (~/code/<name>) PLUS ~/code/sontek (homies, sontek-skills, ...)
# so your own tooling is available in every VM, PLUS ~/screenshots (read-only) so
# dragged screenshots resolve at the same path inside the VM. Bootstrap runs AFTER start (over
# ssh) because Colima's boot-time provision scripts run before DNS is up.
vm-up name cpu="6" memory="6" disk="100" root_disk="100":
  #!/usr/bin/env bash
  set -euo pipefail
  mounts=(--mount "$HOME/code/{{name}}:w")
  # Always include ~/code/sontek, unless this IS the sontek VM (no duplicate mount).
  [ "{{name}}" = "sontek" ] || mounts+=(--mount "$HOME/code/sontek:w")
  # Share ~/screenshots (read-only) at the SAME path so dragging a screenshot into
  # an in-VM agent (aoe/claude) hands it a path that resolves identically in the VM.
  # macOS saves screencaptures here: `defaults write com.apple.screencapture location`.
  mounts+=(--mount "$HOME/screenshots:r")
  # Two sparse disks: --root-disk holds the OS + /nix (the toolchain), --disk is
  # Colima's dedicated container-runtime disk (docker/containerd). The default
  # root disk is only 20 GiB, which /nix overflows, so size it explicitly.
  colima start {{name}} --runtime docker --vm-type vz --mount-type virtiofs --ssh-agent \
    --cpu {{cpu}} --memory {{memory}} --disk {{disk}} --root-disk {{root_disk}} "${mounts[@]}"
  just vm-bootstrap {{name}}

# Provision a running VM (idempotent): ~/code bind mounts, apt prereqs
# (just/rg/curl/build-essential), Nix. Streams output here. Re-runnable any time;
# also used by `vm-up`.
vm-bootstrap name:
  colima ssh -p {{name}} -- bash -s < {{justfile_directory()}}/vm-bootstrap.sh

# Stop a VM (frees RAM/CPU; disk + everything installed inside persists)
vm-down name:
  colima stop {{name}}

# Shell into a VM with the local terminal's identity carried over the SSH hop,
# so OSC 8 hyperlinks (e.g. Claude Code's clickable "PR #NNNN" link), truecolor,
# and other TUI features work -- including inside a remote tmux. colima publishes
# an ssh_config (Host colima-<name>), Include'd from ~/.ssh/config, so we can ssh
# the VM directly. Handles kitty and ghostty; anything else (and inside tmux,
# where TERM is rewritten and these handshakes break) falls back to plain colima
# ssh, where hyperlinks still ride the FORCE_HYPERLINK + tmux xterm*:hyperlinks
# fallback.
vm-ssh name:
  #!/usr/bin/env bash
  set -euo pipefail
  host="colima-{{name}}"
  case "${TERM:-}" in
    *kitty*)
      # kitty: the ssh kitten copies terminfo and sets TERM=xterm-kitty itself
      # (and Claude detects kitty straight from TERM containing "kitty").
      if command -v kitten >/dev/null 2>&1; then exec kitten ssh "$host"; fi
      ;;
    xterm-ghostty)
      # ghostty has no kitten. Push its terminfo to the VM if missing, then force
      # TERM on the remote login shell -- lima's sshd ignores a forwarded/SetEnv
      # TERM, so it only sticks when set in the remote command. Also set
      # TERM_PROGRAM, which is how Claude detects ghostty (TERM alone won't).
      ssh "$host" -- 'infocmp xterm-ghostty >/dev/null 2>&1' \
        || infocmp -x xterm-ghostty | ssh "$host" -- 'tic -x -' >/dev/null 2>&1 || true
      exec ssh -t "$host" -- 'TERM=xterm-ghostty TERM_PROGRAM=ghostty exec "$SHELL" -l'
      ;;
  esac
  exec colima ssh -p {{name}}

# Show a VM's status and address
vm-status name:
  colima status {{name}}

# List all VMs and their state
vm-list:
  colima list

asdf_plugins := "nodejs python golang helm yarn poetry kubectl kustomize terraform terragrunt postgres pnpm sentinel skaffold tilt rust kops"
# Configure ASDF with all desired plugins
setup-asdf:
  @for plugin in {{asdf_plugins}}; do \
      asdf plugin list|grep ${plugin} > /dev/null; \
      if [ $? -ne 0 ]; then \
          echo 'Adding asdf' ${plugin}; \
          asdf plugin add ${plugin}; \
      else \
          echo "Asdf plugin ${plugin} already installed. Removing it"; \
          asdf plugin remove ${plugin}; \
          asdf plugin add ${plugin}; \
      fi \
  done

# Setup development language environments
setup-dev: setup-asdf

setup-krew:
    krew install krew
    kubectl krew install neat
    kubectl krew install oidc-login
    kubectl krew install resource-capacity
    kubectl krew install ctx