Is there any sort of pre-when block functionality that exists?

[efenderbosch-atg]

Asking because we have Spring Data Repo tests and it would be really nice to just have a base repo test that calls entityManager.clear() before the when block to make sure we are actually testing the repo vs the database, not just the 1st level JPA/Hibernate cache.

[szpak]

Spock 2.4-M5 introduced IBlockListener which might be handy in your case (PR: #1575).

Btw, to test that feature, I created an extension which calls "flush" on when block exit. It was a PoC with an idea to streamline it. Would something like that could be applied to your code out of the box, assuming it is finished and released?
https://github.com/szpak/spock-jpa-flush-enforcer/tree/preview3

[Vampire]

Does it have to be right before a when block? Then you need the new block listeners @szpak mentioned.

If you just need it be called before each iteration, you can simply have a base class for your specs where you have a setup method in which you do the call.

Or if you don't want to use a base class, you can also write a simple extension that adds an iteration interceptor or feature method intercepter or whichever is appropriate for your case where you do the call (https://spockframework.org/spock/docs/2.3/all_in_one.html#_interceptors).

This could either be a global extension to work on each and every feature, or you can make it as annotation driven extension that only works on annotated specs or features.

[efenderbosch-atg]

Thanks for the global extension idea. This seems to be working:

class EntityManagerClearingGlobalExtension implements IGlobalExtension {

    private static final IBlockListener BLOCK_LISTENER = new EntityManagerClearingWhereBlockListener()

    @Override
    void visitSpec(SpecInfo spec) {
        boolean isRepoIntegrationSpec = BaseRepositoryIntegrationSpec.isAssignableFrom(spec.reflection)
        if (!isRepoIntegrationSpec) {
            return
        }
        spec.features.forEach { it -> it.addBlockListener(BLOCK_LISTENER) }
    }

    private static class EntityManagerClearingWhereBlockListener implements IBlockListener {

        @Override
        void blockEntered(Specification spec, BlockInfo blockInfo) {
            if (blockInfo.kind != BlockKind.WHEN) {
                return
            }
            if (!(spec instanceof BaseRepositoryIntegrationSpec)) {
                return
            }
            spec.entityManager.clear()
        }

    }

}

And here's the base repo spec:

@DataJpaTest
@CompileStatic
@ActiveProfiles('local')
@AutoConfigureTestDatabase(replace = NONE)
@SuppressWarnings('AbstractClassWithoutAbstractMethod')
abstract class BaseRepositoryIntegrationSpec extends Specification {

    @Autowired
    protected EntityManager entityManager

}

[Vampire]

If you anyway ignore all specs not derived from that base spec, why don't you create an annotation-driven extension and annotate the base-spec with it?

[Vampire]

Btw. are you sure you want to execute this before each when block entered, even if there are multiple in one feature method?

And your class name is off a bit, it suggests you care about where, not when :-)