confidence-sdk-android/Provider/build.gradle.kts at e2d93d67ac1fefc388a4d0d2019546d86035a104 · spotify/confidence-sdk-android · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
// ktlint-disable max-line-length
plugins {
    alias(libs.plugins.androidLibrary)
    alias(libs.plugins.kotlinAndroid)
    id("maven-publish")
    alias(libs.plugins.ktlint)
    alias(libs.plugins.kotlinSerialization) apply true
    id("signing")
    alias(libs.plugins.binaryCompatibilityValidation)
    alias(libs.plugins.kover)
}

val providerVersion = project.extra["version"].toString()

android {
    namespace = "com.spotify.confidence.openfeature"
    compileSdk = 33

    defaultConfig {
        minSdk = 21
        version = providerVersion

        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
    }

    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_11
        targetCompatibility = JavaVersion.VERSION_11
    }
    kotlinOptions {
        jvmTarget = JavaVersion.VERSION_11.toString()
    }

    publishing {
        singleVariant("release") {
            withJavadocJar()
            withSourcesJar()
        }
    }
    testOptions {
        unitTests.isReturnDefaultValues = true
    }
}

dependencies {
    api(libs.openFeatureSDK)
    implementation(libs.okHttp)
    implementation(libs.kotlinxSerialization)
    implementation(libs.coroutines)
    api(project(":Confidence"))
    testImplementation(libs.junit)
    testImplementation(libs.coroutines)
    testImplementation(libs.kotlinMockito)
    testImplementation(libs.mockWebServer)
    testImplementation(libs.kotlinxCoroutinesTest)
    testImplementation(libs.mockk)
}

publishing {
    publications {
        register<MavenPublication>("release") {
            groupId = project.extra["groupId"].toString()
            artifactId = "openfeature-provider-android"
            version = providerVersion

            pom {
                name.set("Confidence Openfeature Provider Android")
                description.set("An Openfeature Provider for Confidence, made for the Android SDK")
                url.set("https://github.com/spotify/confidence-sdk-android")
                licenses {
                    license {
                        name.set("The Apache License, Version 2.0")
                        url.set("http://www.apache.org/licenses/LICENSE-2.0.txt")
                    }
                }
                developers {
                    developer {
                        id.set("vahidlazio")
                        name.set("Vahid Torkaman")
                        email.set("vahidt@spotify.com")
                    }
                    developer {
                        id.set("fabriziodemaria")
                        name.set("Fabrizio Demaria")
                        email.set("fdema@spotify.com")
                    }
                    developer {
                        id.set("nicklasl")
                        name.set("Nicklas Lundin")
                        email.set("nicklasl@spotify.com")
                    }
                    developer {
                        id.set("nickybondarenko")
                        name.set("Nicky Bondarenko")
                        email.set("nickyb@spotify.com")
                    }
                }
                scm {
                    connection.set(
                        "scm:git:git://spotify/confidence-sdk-android.git"
                    )
                    developerConnection.set(
                        "scm:git:ssh://spotify/confidence-sdk-android.git"
                    )
                    url.set("https://github.com/spotify/confidence-sdk-android")
                }
            }
            afterEvaluate {
                from(components["release"])
            }
        }
    }
}

signing {
    sign(publishing.publications["release"])
}

kover {
    reports {
        verify {
            rule {
                minBound(80)
            }
        }
    }
}