ferrostar/android/ui-maplibre-car-app/build.gradle at 7c02ed4d1d16c49425dff72bf18977629cb9ea49 · stadiamaps/ferrostar · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
import com.vanniktech.maven.publish.AndroidSingleVariantLibrary
import com.vanniktech.maven.publish.JavadocJar
import com.vanniktech.maven.publish.SourcesJar

plugins {
    alias libs.plugins.androidLibrary
    alias libs.plugins.ktfmt
    alias libs.plugins.compose.compiler
    alias libs.plugins.mavenPublish
}

android {
    namespace 'com.stadiamaps.ferrostar.ui.maplibre.car.app'
    compileSdk {
        version = release(36)
    }

    defaultConfig {
        minSdk 29

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFiles "consumer-rules.pro"
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        coreLibraryDesugaringEnabled true
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    buildFeatures {
        compose true
    }
}

dependencies {
    // For as long as we support API 25; once we can raise support to 26, all is fine
    coreLibraryDesugaring libs.desugar.jdk.libs

    implementation libs.androidx.ktx
    implementation libs.androidx.appcompat
    implementation libs.material

    implementation platform(libs.androidx.compose.bom)
    implementation libs.androidx.compose.ui
    implementation libs.androidx.compose.ui.graphics
    implementation libs.androidx.compose.ui.tooling
    implementation libs.androidx.compose.material3
    api libs.car.app.compose

    implementation project(':core')
    implementation project(':ui-compose')
    implementation project(':ui-maplibre')

    testImplementation libs.junit
    androidTestImplementation libs.androidx.test.junit
    androidTestImplementation libs.androidx.test.espresso
}

mavenPublishing {
    publishToMavenCentral()

    if (!project.hasProperty(SKIP_SIGNING_PROPERTY)) {
        signAllPublications()
    }

    configure(new AndroidSingleVariantLibrary(
            // Temporarily disable JavaDoc due to dokka issues with the Compose library using newer bytecode
            new JavadocJar.Empty(),
            new SourcesJar.Sources(),
            "release"
    ))

    apply from: "${rootProject.projectDir}/common-pom.gradle"

    pom {
        name = "Ferrostar MapLibre Android Auto UI"
        description = "Composable map UI car app components for Ferrostar built with MapLibre"

        commonPomConfig(it, true)
    }
}