sound-categories/build.gradle at main · stashingco/sound-categories · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
plugins {
    id "fabric-loom" version "0.12-SNAPSHOT"
    id "maven-publish"
    id "com.matthewprenger.cursegradle" version "1.4.0"
    id "com.modrinth.minotaur" version "2.2.0"
    id "org.jetbrains.changelog" version "1.3.1"
}

sourceCompatibility = JavaVersion.VERSION_16
targetCompatibility = JavaVersion.VERSION_16

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

var modVersion = project.version.split("\\+")[0]
var compatibleWith = []

var split = project.minecraft_version.split('\\.')
if (split.length == 3) {
    var base = split[0] + "." + split[1]
    compatibleWith.add(base)
    for (int i = Integer.parseInt(split[2]); i > 0; i--)
        compatibleWith.add(base + "." + i)
} else compatibleWith.add(project.minecraft_version)

repositories {
    maven {
        name = "stashymane's repo"
        url = "https://repo.stashy.dev"
    }
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.api_version}"
}

loom {
    accessWidenerPath = file("src/main/resources/soundcategories.accesswidener")
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.encoding = "UTF-8"

    def targetVersion = 17
    if (JavaVersion.current().isJava9Compatible()) {
        it.options.release = targetVersion
    }
}

java {
    withSourcesJar()
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archivesBaseName}" }
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifact(remapJar) {
                builtBy remapJar
            }
            artifact(sourcesJar) {
                builtBy remapSourcesJar
            }
        }
    }

    repositories {
        maven {
            url = "https://repo.stashy.dev"
            credentials {
                username = project.hasProperty("publish_username") ? project.publish_username : ""
                password = project.hasProperty("publish_password") ? project.publish_password : ""
            }
        }
    }
}

changelog {
    version = modVersion
}

curseforge {
    apiKey = System.getenv("CURSE_API_KEY") ?: ""
    project {
        id = "557374"
        changelog = project.changelog.get(modVersion).toHTML()
        changelogType = "html"
        releaseType = "release"
        for (String ver : compatibleWith)
            addGameVersion ver

        mainArtifact(remapJar) {
            displayName = "$modVersion for $project.minecraft_version"
            relations {
                requiredDependency("fabric-api")
            }
        }
    }

    options {
        forgeGradleIntegration = false
        detectNewerJava = true
    }
}

modrinth {
    token = System.getenv("MODRINTH_TOKEN") ?: ""
    changelog = project.changelog.get(modVersion).toText()
    projectId = "GROGt4v1"
    versionNumber = version
    versionName = "$modVersion for $project.minecraft_version"
    uploadFile = remapJar
    gameVersions = compatibleWith
    loaders = ["fabric"]
}

task publishMod() {
    dependsOn(tasks.modrinth)
    dependsOn(tasks.curseforge)
}

gradleEnterprise {
    buildScan {
        termsOfServiceUrl = "https://gradle.com/terms-of-service"
        termsOfServiceAgree = "yes"
    }
}