snapcache/flake.nix at master · staticweb-io/snapcache · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
{
  description = "SnapCache plugin for WordPress";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      ...
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      with import nixpkgs { inherit system; };
      with pkgs;
      let
        name = "snapcache";
        version = "1.0.0";
        composerSrc = pkgs.lib.cleanSourceWith {
          src = self;
          filter =
            path: type:
            let
              rel = baseNameOf path;
            in
            rel == "composer.json" || rel == "composer.lock";
        };
        composerVendor = php.mkComposerVendor (finalAttrs: {
          composerNoDev = false;
          pname = "${name}-composer-deps-dev";
          version = "1.0.0";
          src = composerSrc;
          vendorHash = "sha256-4mlQzUtBVFndTOiOSzkJdV6yb5+gqYnfYtufrr+RZfY=";
        });
        snapCacheSrc = pkgs.lib.cleanSourceWith {
          src = self;
          filter =
            path: type:
            let
              base = baseNameOf path;
            in
            type == "directory" && base == "src"
            || pkgs.lib.hasInfix "/src/" path
            || type == "directory" && base == "tests"
            || pkgs.lib.hasInfix "/tests/" path
            || type == "directory" && base == "util"
            || pkgs.lib.hasInfix "/util/" path
            || type == "directory" && base == "views"
            || pkgs.lib.hasInfix "/views/" path
            || type == "regular" && pkgs.lib.hasSuffix ".php" base
            || base == "composer.json"
            || base == "composer.lock"
            || base == "justfile"
            || base == "phpcs.xml"
            || base == "phpunit.xml"
            || base == "readme.txt";
        };
        releaseExtras = pkgs.lib.cleanSourceWith {
          src = self;
          filter =
            path: type:
            let
              base = baseNameOf path;
            in
            type == "directory" && base == "release" || pkgs.lib.hasInfix "/release/" path;
        };
        buildsnapCacheSrc =
          constantsFile:
          runCommand "snapcache-source"
            {
              nativeBuildInputs = [
                just
                php
                phpPackages.composer
              ];
            }
            ''
              export PLUGIN_DIR="$TMPDIR/${name}"
              mkdir -p "$PLUGIN_DIR"
              cp -r --no-preserve=mode "${composerVendor}/vendor" .
              cp -r --no-preserve=mode "${snapCacheSrc}"/* .

              # Lock certain constants and run rector to remove dead code
              cp ${constantsFile} constants.php
              just rector

              composer install --no-cache --no-dev --optimize-autoloader

              mkdir -p "$out"
              cp -r composer.json readme.txt snapcache.php src uninstall.php vendor "$out"
            '';
        snapCacheWpOrgSrc = buildsnapCacheSrc "${releaseExtras}/release/wp-org/constants.php";
        snapCacheGitHubSrc = buildsnapCacheSrc "${releaseExtras}/release/github/constants.php";
        pluginZip =
          source:
          runCommand name { } ''
            mkdir "$TMPDIR/${name}"
            cd "$TMPDIR/${name}"
            ln -s "${source}" "${name}"
            mkdir -p "$out"
            ${zip}/bin/zip -r -9 "$out"/"${name}.zip" "${name}"
          '';
        snapCache = pluginZip snapCacheGitHubSrc;
        snapCacheWpOrg = pluginZip snapCacheWpOrgSrc;
        snapCacheCheck = stdenv.mkDerivation {
          pname = "snapcache-check";
          version = version;

          src = snapCacheSrc;

          nativeBuildInputs = [
            bash
            php
          ];
          nativeCheckInputs = [
            jq
            just
            phpPackages.composer
          ];

          doCheck = true;
          dontUseJustInstall = true;

          buildPhase = ''
            mkdir -p $out
          '';

          checkPhase = ''
            export PLUGIN_DIR="$TMPDIR/${name}"
            mkdir -p "$PLUGIN_DIR"
            cd "$PLUGIN_DIR"
            cp -a "${composerVendor}/vendor" .
            cp -r --no-preserve=mode "$src"/* .
            just _check_no_test
          '';
        };
      in
      {
        checks = { inherit snapCacheCheck; };
        lib = { inherit snapCacheSrc; };
        packages = {
          inherit composerVendor snapCache;
          plugin = snapCache;
          pluginGitHubSrc = snapCacheGitHubSrc;
          pluginWpOrg = snapCacheWpOrg;
          pluginWpOrgSrc = snapCacheWpOrgSrc;
        };
      }
    );
}