yavascript/flake.nix at main · suchipi/yavascript · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  };

  outputs = { self, nixpkgs }:
    let
      inherit (nixpkgs) lib;

      makePackages = (system:
        let
          pkgs = import nixpkgs {
            inherit system;
          };
        in
        {
          default = pkgs.buildNpmPackage rec {
            pname = "yavascript";
            version =
              let
                sha = builtins.substring 0 12 (self.rev or self.dirtyRev);
                dirty = lib.strings.optionalString (self ? dirtyRev) "-dirty";
              in
              "git-${sha}${dirty}";

            src = ./.;

            npmConfigHook = pkgs.importNpmLock.npmConfigHook;
            npmDeps = pkgs.importNpmLock {
              npmRoot = src;
            };

            SKIP_FNM_USE = 1;
            SKIP_NPM_INSTALL = 1;
            YAVASCRIPT_VERSION = version;

            preBuild = ''
              patchShebangs meta
            '';

            nativeBuildInputs = with pkgs; [
              ninja
            ];
            dontUseNinjaBuild = true;
            dontUseNinjaInstall = true;

            installPhase = ''
              mkdir -p $out/bin
              cp -r dist $out/
              mv \
                $out/dist/yavascript \
                $out/dist/yavascript-bootstrap \
                $out/bin/
            '';
          };
        }
      );
    in
    builtins.foldl' lib.recursiveUpdate { } (builtins.map
      (system: {
        devShells.${system} = makePackages system;
        packages.${system} = makePackages system;
      })
      lib.systems.flakeExposed);
}