swift-corelibs-foundation/Sources/FoundationXML/CMakeLists.txt at fcd833c021a62178fb1c4a876de76bd2f2a2c473 · swiftlang/swift-corelibs-foundation · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
##===----------------------------------------------------------------------===##
##
## This source file is part of the Swift open source project
##
## Copyright (c) 2024 Apple Inc. and the Swift project authors
## Licensed under Apache License v2.0
##
## See LICENSE.txt for license information
## See CONTRIBUTORS.md for the list of Swift project authors
##
## SPDX-License-Identifier: Apache-2.0
##
##===----------------------------------------------------------------------===##

add_library(FoundationXML
    CFAccess.swift
    XMLDocument.swift
    XMLDTD.swift
    XMLDTDNode.swift
    XMLElement.swift
    XMLNode.swift
    XMLParser.swift)

target_compile_options(FoundationXML PRIVATE
    "SHELL:$<$<COMPILE_LANGUAGE:Swift>:${_Foundation_swift_build_flags}>")

target_link_libraries(FoundationXML
    PRIVATE
        _CFXMLInterface
    PUBLIC
        Foundation)

if(NOT BUILD_SHARED_LIBS)
    target_compile_options(FoundationXML PRIVATE
        "SHELL:$<$<COMPILE_LANGUAGE:Swift>:-Xfrontend -public-autolink-library -Xfrontend _CFXMLInterface>")
    if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
        target_compile_options(FoundationXML PRIVATE
            "SHELL:$<$<COMPILE_LANGUAGE:Swift>:-Xfrontend -public-autolink-library -Xfrontend libxml2s>")
    else()
        target_compile_options(FoundationXML PRIVATE
            "SHELL:$<$<COMPILE_LANGUAGE:Swift>:-Xfrontend -public-autolink-library -Xfrontend xml2>")
    endif()
    target_compile_options(FoundationXML PRIVATE
        "SHELL:$<$<COMPILE_LANGUAGE:Swift>:-Xfrontend -public-autolink-library -Xfrontend $<$<PLATFORM_ID:Windows>:${CMAKE_STATIC_LIBRARY_PREFIX_Swift}>swiftSynchronization>")

    if(BUILD_FULLY_STATIC)
        target_compile_options(FoundationXML
            PRIVATE
              "SHELL:$<$<COMPILE_LANGUAGE:Swift>:-Xfrontend -public-autolink-library -Xfrontend z>")
    endif()

endif()

if(LINKER_SUPPORTS_BUILD_ID)
  target_link_options(FoundationXML PRIVATE "LINKER:--build-id=sha1")
endif()

set_property(GLOBAL APPEND PROPERTY Foundation_EXPORTS FoundationXML)
_foundation_install_target(FoundationXML)