Preview SQLite schema, Excel, Parquet/Arrow/Avro with Nushell and Piper

[beskep]

preview.nu

def trim-quotes [] {
  $in | str trim --char '"' | str trim --char "'"
}

def main [] {
  help main
}

def 'main sqlite' [path: path] {
  print $'(ansi blue)SQLite Schema(ansi reset)'
  $path | trim-quotes | open $in | schema | get tables | to yaml | print
}

def 'main xlsx' [
  path: path
  nrows: int = 20
  ncols: int = 10
] {
  let raw = $path | trim-quotes | open --raw $in | from xlsx
  let sheets = $raw | columns

  if ($sheets | length) != 1 {
    print $'(ansi blue)sheets(ansi reset) = ($sheets)'
  }

  let table = $raw | get ($sheets | get 0)
  let shape = {
    rows: ($table | length)
    columns: ($table | columns | length)
  }
  print $'(ansi blue)shape(ansi reset) = ($shape)'

  let columns = $table | columns | first $ncols
  print $'(ansi blue)sample(ansi reset)'
  $table
  | select ...$columns
  | table --theme compact --index false -a $nrows
  | print
}

# needs polars plugin (plugin add nu_plugin_polars.exe)
def polars-summary [
  data
  max_rows: int = 1000
] {
  let summary = $data
    | polars first $max_rows
    | polars summary -q []
    | polars collect
  let cols = $summary | polars drop descriptor | polars columns
  $summary
  | polars unpivot -i [descriptor] -o $cols
  | polars pivot --on descriptor --on-cols [count sum mean std min median max] --values value --index variable
  | polars collect
}

def 'main polars' [
  path: path
  nrows: int = 100
  --summary
] {
  let lf = $path | trim-quotes | polars open $in

  let shape = $lf | polars shape | polars into-nu | get 0
  print $'(ansi blue)shape(ansi reset) = ($shape)'

  if $summary {
    print $'(ansi blue)summary(ansi reset)'
    print (polars-summary $lf)
  } else {
    let schema = $lf | polars schema | transpose variable dtype
    let head = $lf
      | polars first 1
      | polars into-nu
      | transpose variable head

    print $'(ansi blue)schema(ansi reset)'
    $schema | join $head variable | table --theme compact | print
  }

  print $'(ansi blue)repr(ansi reset)'
  $lf | polars first $nrows | polars into-repr | print
}

yazi.toml

[plugin]
prepend_previewers = [
  { mime = "application/sqlite3", run = "piper -- nu ~/.local/bin/preview.nu sqlite $1" },
  { url = "*.{xlsx,xlsm}", run = "piper -- nu ~/.local/bin/preview.nu xlsx $1" },
  { url = "*.{arrow,avro,parquet}", run = "piper -- nu ~/.local/bin/preview.nu polars $1" },
]

If you want to use piper in Windows, see yazi-rs/plugins#148