build.gradle

description = '''Spring Boot AutoConfigure for Temporal Java SDK'''

ext {
    otelVersion = '1.55.0'
    otShimVersion = "${otelVersion}-alpha"
}

dependencies {
    api(platform("org.springframework.boot:spring-boot-dependencies:$springBootVersion"))
    api(platform("io.opentelemetry:opentelemetry-bom:$otelVersion"))

    compileOnly project(':temporal-sdk')
    compileOnly project(':temporal-testing')

    api "org.springframework.boot:spring-boot-autoconfigure"

    api project(':temporal-opentracing')
    implementation "io.opentelemetry:opentelemetry-api"
    implementation "io.opentelemetry:opentelemetry-opentracing-shim:$otShimVersion"

    if (JavaVersion.current().isJava9Compatible()) {
        //needed for the generated grpc stubs and is not a part of JDK since java 9
        compileOnly "javax.annotation:javax.annotation-api:$annotationApiVersion"
    }

    // this dependency is not mandatory for the module to work, but it provides a better IDE experience developing the module
    // it's needed to auto-generate configuration metadata. See for more details:
    // https://docs.spring.io/spring-boot/docs/2.4.0/reference/html/appendix-configuration-metadata.html#configuration-metadata-annotation-processor
    annotationProcessor "org.springframework.boot:spring-boot-configuration-processor:$springBootVersion"

    testImplementation project(':temporal-testing')

    testImplementation "org.mockito:mockito-core:${mockitoVersion}"
    testImplementation group: 'ch.qos.logback', name: 'logback-classic', version: "${logbackVersion}"

    testImplementation "org.springframework.boot:spring-boot-starter-test"

    testImplementation('org.slf4j:slf4j-api') {
        version {
            strictly "${slf4jVersion}"
        }
    }
}

tasks.test {
    useJUnitPlatform()
    testLogging {
        events("passed", "skipped", "failed")
    }
}