settings.gradle

buildscript {
    repositories {
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath "gradle.plugin.ch.myniva.gradle:s3-build-cache:0.10.0"
        classpath "com.gradle.enterprise:com.gradle.enterprise.gradle.plugin:3.17.4"
        classpath "com.gradle:common-custom-user-data-gradle-plugin:2.0.1"
    }
}

apply plugin: 'com.gradle.develocity'
apply plugin: "com.gradle.common-custom-user-data-gradle-plugin"

rootProject.name = 'testcontainers-examples'

includeBuild '..'

// explicit include to allow Dependabot to autodiscover subprojects
include 'kafka-cluster'
include 'linked-container'
include 'neo4j-container'
include 'redis-backed-cache'
include 'redis-backed-cache-testng'
include 'selenium-container'
include 'singleton-container'
include 'solr-container'
include 'spring-boot'
include 'cucumber'
include 'spring-boot-kotlin-redis'
include 'immudb'
include 'zookeeper'
include 'hazelcast'
include 'nats'
include 'sftp'
include 'ollama-hugging-face'

ext.isCI = System.getenv("CI") != null

buildCache {
    local {
        enabled = !isCI
    }
    remote(develocity.buildCache) {
        push = isCI && !System.getenv("READ_ONLY_REMOTE_GRADLE_CACHE") && System.getenv("DEVELOCITY_ACCESS_KEY")
        enabled = true
    }
}

develocity {
    buildScan {
        server = "https://ge.testcontainers.org/"
        publishing.onlyIf {
            it.authenticated
        }
        uploadInBackground = !isCI
        capture.fileFingerprints = true
    }

}