build.gradle

plugins {
    id 'java'
    id 'com.gradleup.shadow' version '9.4.1'
    id 'jacoco'
}

group = 'de.thomasuebel.mc.ts3bridge'
version = '1.1.8-SNAPSHOT'

java {
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

repositories {
    mavenCentral()
    maven { url = 'https://repo.papermc.io/repository/maven-public/' }
}

dependencies {
    compileOnly 'io.papermc.paper:paper-api:1.21.1-R0.1-SNAPSHOT'

    implementation 'com.github.theholywaffle:teamspeak3-api:1.3.0'
    implementation 'com.google.code.gson:gson:2.10.1'
    implementation("org.bstats:bstats-bukkit:3.2.1")

    testImplementation platform('org.junit:junit-bom:5.10.2')
    testImplementation 'org.junit.jupiter:junit-jupiter'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
    testImplementation 'org.mockito:mockito-core:5.15.2'
    testImplementation 'org.mockito:mockito-junit-jupiter:5.15.2'
    testImplementation 'io.papermc.paper:paper-api:1.21.1-R0.1-SNAPSHOT'
}

processResources {
    inputs.property('version', project.version)
    filesMatching('plugin.yml') {
        expand(version: project.version)
    }
}

test {
    useJUnitPlatform()
    finalizedBy jacocoTestReport
}

jacocoTestReport {
    dependsOn test
    reports {
        xml.required = true
    }
    // MctsPlugin is framework wiring (JavaPlugin lifecycle); testable only via integration tests.
    // TeamspeakConnection wraps the HolyWaffle TS3 client; it requires a live ServerQuery port.
    // Both are excluded from coverage metrics to avoid deflating the reported percentage.
    classDirectories.setFrom(
        fileTree(dir: layout.buildDirectory.dir('classes/java/main').get().asFile, excludes: [
            'de/thomasuebel/mc/ts3bridge/minecraft/MctsPlugin.class',
            'de/thomasuebel/mc/ts3bridge/teamspeak/TeamspeakConnection.class'
        ])
    )
}

shadowJar {
    // Relocation disabled: Paper's plugin classloader provides isolation.
    // Re-enable if classpath conflicts arise with other plugins.
    archiveClassifier = ''
    // bStats must always be relocated to avoid version conflicts with other plugins.
    relocate 'org.bstats', 'de.thomasuebel.mc.ts3bridge.bstats'
}

build.dependsOn shadowJar