audio: rework modules, forward pipewire socket to gui-vm

- introduced 'server' and 'client' configs
- audio-vm is now the 'server', in charge of all audio hw
- all other systems are now 'clients'
- 'clients' can optionally enable pw socket forwarding
- removed all audio-related configs from gui-vm/cosmic
- removed ghaf-audio namespace
- removed ghaf audio control tool, replaced by pavucontrol
- re-enabled all sound-related settings in cosmic DE

Signed-off-by: Kajus Naujokaitis <kajus.naujokaitis@unikie.com>

Author: kajusnau

modules/common/services/audio.nix

@@ -0,0 +1,87 @@
+# SPDX-FileCopyrightText: 2026 TII (SSRC) and the Ghaf contributors
+# SPDX-License-Identifier: Apache-2.0
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}:
+let
+  cfg = config.ghaf.services.audio;
+  host = "audio-vm";
+  address = "tcp:${host}:${toString cfg.server.pulseaudioTcpPort}";
+
+in
+{
+  options.ghaf.services.audio = {
+    client = {
+      remotePulseServerAddress = lib.mkOption {
+        type = lib.types.str;
+        default = address;
+        defaultText = "tcp:audio-vm:4714";
+        description = ''
+          Address of the remote PulseAudio server to connect to.
+
+          This should point to the main Ghaf audio server.
+        '';
+      };
+      enablePipewireControl = lib.mkEnableOption ''
+        PipeWire control via a forwarded pipewire socket from the server to this machine.
+
+        The PipeWire socket will be available at `/tmp/pipewire-0`.
+        To use it, set the `PIPEWIRE_RUNTIME_DIR` environment variable to /tmp.
+        `PIPEWIRE_RUNTIME_DIR` can be set for the entire session but is not recommended,
+        as it may interfere with local PipeWire instances.
+
+        Should only be used on gui-vm where users need to control audio settings.
+
+        Requires givc to be enabled on both client and server.
+        PipeWire socket forwarding must be enabled on the server as well.
+      '';
+    };
+  };
+  config = lib.mkMerge [
+    {
+      environment = {
+        systemPackages = [ pkgs.pulseaudio ];
+        sessionVariables = {
+          PULSE_SERVER = "${cfg.client.remotePulseServerAddress}";
+        };
+        variables = {
+          PULSE_SERVER = "${cfg.client.remotePulseServerAddress}";
+        };
+      };
+    }
+    (lib.mkIf cfg.client.enablePipewireControl {
+      assertions = [
+        {
+          assertion = config.system.name == "gui-vm";
+          message = "PipeWire control forwarding can only be enabled on gui-vm.";
+        }
+        {
+          assertion = config.ghaf.givc.enable;
+          message = "GIVC must be enabled on audio clients when enabling Ghaf audio server control forwarding.";
+        }
+      ];
+
+      environment = {
+        systemPackages = with pkgs; [
+          pipewire
+          pwvucontrol-gui
+        ];
+      };
+
+      givc.sysvm.socketProxy = [
+        {
+          transport = {
+            name = "audio-vm";
+            addr = config.ghaf.networking.hosts."audio-vm".ipv4;
+            port = "9013";
+            protocol = "tcp";
+          };
+          socket = "/tmp/pipewire-0";
+        }
+      ];
+    })
+  ];
+}

modules/common/services/audio/client.nix

@@ -0,0 +1,28 @@
+# SPDX-FileCopyrightText: 2022-2026 TII (SSRC) and the Ghaf contributors
+# SPDX-License-Identifier: Apache-2.0
+{
+  lib,
+  ...
+}:
+{
+  imports = [
+    ./server.nix
+    ./client.nix
+  ];
+
+  options.ghaf.services.audio = {
+    enable = lib.mkEnableOption "Enable Ghaf audio services";
+    role = lib.mkOption {
+      type = lib.types.enum [
+        "server"
+        "client"
+      ];
+      default = "client";
+      description = ''
+        The role of this VM in the Ghaf audio topology.
+        - "server" controls audio hardware and runs the main audio server
+        - "client" connects to the audio server to play/record (and optionally control) audio
+      '';
+    };
+  };
+}