fix(alien): add network card driver

Add package for ethernet card driver and include in alienware.

Signed-off-by: Manuel Bluhm <manuel@ssrc.tii.ae>

Author: mbssrc

modules/reference/hardware/alienware/net-config.nix

@@ -0,0 +1,12 @@
+# Copyright 2025 TII (SSRC) and the Ghaf contributors
+# SPDX-License-Identifier: Apache-2.0
+{
+  config,
+  pkgs,
+  ...
+}:
+{
+  config = {
+    boot.extraModulePackages = [ pkgs.rtl8126 ];
+  };
+}

modules/reference/hardware/flake-module.nix

@@ -12,6 +12,9 @@
         ghaf.virtualization.microvm.guivm.extraModules = [
           (import ./alienware/extra-config.nix)
         ];
+        ghaf.virtualization.microvm.netvm.extraModules = [
+          (import ./alienware/net-config.nix)
+        ];
       }
     ];
     hardware-dell-latitude-7230.imports = [

packages/own-pkgs-overlay.nix

@@ -26,6 +26,7 @@
     memsocket = final.callPackage ./pkgs-by-name/memsocket/package.nix { };
     open-normal-extension = final.callPackage ./pkgs-by-name/open-normal-extension/package.nix { };
     qemuqmp = final.callPackage ./pkgs-by-name/qemuqmp/package.nix { };
+    rtl8126 = final.callPackage ./pkgs-by-name/rtl8126/package.nix { };
     vhotplug = final.callPackage ./pkgs-by-name/vhotplug/package.nix { };
     vinotify = final.callPackage ./pkgs-by-name/vinotify/package.nix { };
     vsockproxy = final.callPackage ./pkgs-by-name/vsockproxy/package.nix { };

packages/pkgs-by-name/rtl8126/package.nix

@@ -0,0 +1,57 @@
+# Copyright 2022-2024 TII (SSRC) and the Ghaf contributors
+# SPDX-License-Identifier: Apache-2.0
+#
+#
+# https://github.com/davidkna/nixpkgs/blob/6853dcf3c8ac1492a35d54a62da2233a35286810/pkgs/os-specific/linux/r8126/default.nix
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  linuxPackages,
+}:
+let
+  inherit (linuxPackages) kernel;
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "r8126";
+  # On update please verify (using `diff -r`) that the source matches the
+  # realtek version.
+  version = "10.014.01";
+
+  # This is a mirror. The original website[1] doesn't allow non-interactive
+  # downloads.
+  # [1] https://www.realtek.com/Download/List?cate_id=584
+  src = fetchFromGitHub {
+    owner = "openwrt";
+    repo = "rtl8126";
+    tag = finalAttrs.version;
+    hash = "sha256-NSi95L5PN+o9z7N3zFjcYk2nQjY03csUBp0saakaqlE=";
+  };
+
+  hardeningDisable = [ "pic" ];
+
+  nativeBuildInputs = kernel.moduleBuildDependencies;
+
+  preBuild = ''
+    substituteInPlace Makefile --replace-fail "BASEDIR :=" "BASEDIR ?="
+    substituteInPlace Makefile --replace-fail "modules_install" "INSTALL_MOD_PATH=$out modules_install"
+  '';
+
+  makeFlags = [
+    "BASEDIR=${kernel.dev}/lib/modules/${kernel.modDirVersion}"
+  ];
+
+  buildFlags = [ "modules" ];
+
+  meta = {
+    homepage = "https://github.com/openwrt/rtl8126";
+    downloadPage = "https://www.realtek.com/Download/List?cate_id=584";
+    description = "Realtek r8126 driver";
+    longDescription = ''
+      A kernel module for Realtek 8126 5G network cards.
+    '';
+    license = lib.licenses.gpl2Only;
+    platforms = lib.platforms.linux;
+    maintainers = [ lib.maintainers.davidkna ];
+  };
+})