forked from microsoft/ALAppExtensions
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathShpfyShop.Table.al
1027 lines (976 loc) · 36.4 KB
/
ShpfyShop.Table.al
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
namespace Microsoft.Integration.Shopify;
using Microsoft.Finance.GeneralLedger.Account;
using System.Globalization;
using System.IO;
using Microsoft.Sales.Customer;
using Microsoft.Sales.Pricing;
using Microsoft.Finance.Currency;
using Microsoft.Finance.GeneralLedger.Setup;
using Microsoft.Finance.VAT.Setup;
using Microsoft.Finance.SalesTax;
using Microsoft.Foundation.Address;
using Microsoft.Inventory.Item;
using System.Security.AccessControl;
using System.DataAdministration;
using System.Privacy;
using System.Threading;
using Microsoft.Inventory.Location;
/// <summary>
/// Table Shpfy Shop (ID 30102).
/// </summary>
table 30102 "Shpfy Shop"
{
Caption = 'Shopify Shop';
DataClassification = SystemMetadata;
DrillDownPageId = "Shpfy Shops";
LookupPageId = "Shpfy Shops";
fields
{
field(1; "Code"; Code[20])
{
Caption = 'Code';
DataClassification = SystemMetadata;
NotBlank = true;
}
field(2; "Shopify URL"; Text[250])
{
Caption = 'Shopify URL';
Access = Internal;
DataClassification = SystemMetadata;
ExtendedDatatype = URL;
trigger OnValidate()
var
AuthenticationMgt: Codeunit "Shpfy Authentication Mgt.";
begin
if ("Shopify URL" <> '') then begin
if not "Shopify URL".ToLower().StartsWith('https://') then
"Shopify URL" := CopyStr('https://' + "Shopify URL", 1, MaxStrLen("Shopify URL"));
if "Shopify URL".ToLower().StartsWith('https://admin.shopify.com/store/') then
"Shopify URL" := CopyStr('https://' + "Shopify URL".Replace('https://admin.shopify.com/store/', '').Split('/').Get(1) + '.myshopify.com', 1, MaxStrLen("Shopify URL"));
if not AuthenticationMgt.IsValidShopUrl("Shopify URL") then
Error(InvalidShopUrlErr);
end;
Rec.CalcShopId();
end;
}
field(3; Enabled; Boolean)
{
Caption = 'Enabled';
trigger OnValidate()
var
CustomerConsentMgt: Codeunit "Customer Consent Mgt.";
WebhooksMgt: Codeunit "Shpfy Webhooks Mgt.";
begin
if Rec."Enabled" then begin
Rec.TestField("Shopify URL");
Rec."Enabled" := CustomerConsentMgt.ConfirmUserConsent();
end else begin
Rec.Enabled := true;
Rec.Validate("Order Created Webhooks", false);
WebhooksMgt.DisableBulkOperationsWebhook(Rec, CompanyName());
Rec.Enabled := false;
end;
end;
}
field(5; "Log Enabled"; Boolean)
{
Caption = 'Log Enabled';
DataClassification = SystemMetadata;
ObsoleteReason = 'Replaced with field "Logging Mode"';
#if not CLEAN23
ObsoleteState = Pending;
ObsoleteTag = '23.0';
#else
ObsoleteState = Removed;
ObsoleteTag = '25.0';
#endif
}
field(6; "Customer Price Group"; Code[10])
{
Caption = 'Customer Price Group';
DataClassification = SystemMetadata;
TableRelation = "Customer Price Group";
ValidateTableRelation = true;
}
field(7; "Customer Discount Group"; Code[20])
{
Caption = 'Customer Discount Group';
DataClassification = SystemMetadata;
TableRelation = "Customer Discount Group";
ValidateTableRelation = true;
}
field(8; "Shipping Charges Account"; Code[20])
{
Caption = 'Shipping Charges Account';
DataClassification = SystemMetadata;
TableRelation = "G/L Account"."No.";
ValidateTableRelation = true;
trigger OnValidate()
var
GLAccount: Record "G/L Account";
begin
if GLAccount.Get("Shipping Charges Account") then
CheckGLAccount(GLAccount);
end;
}
field(9; "Language Code"; Code[10])
{
Caption = 'Language Code';
DataClassification = SystemMetadata;
TableRelation = Language;
ValidateTableRelation = true;
}
field(10; "Sync Item"; Option)
{
Caption = 'Sync Item';
DataClassification = SystemMetadata;
OptionCaption = ' ,To Shopify,From Shopify';
OptionMembers = " ","To Shopify","From Shopify";
}
field(11; "Item Template Code"; Code[10])
{
Caption = 'Item Template Code';
DataClassification = SystemMetadata;
TableRelation = "Config. Template Header".Code where("Table Id" = const(27));
ValidateTableRelation = true;
ObsoleteReason = 'Replaced by Item Templ. Code';
ObsoleteState = Removed;
ObsoleteTag = '25.0';
}
field(12; "Sync Item Images"; Option)
{
Caption = 'Sync Item Images';
DataClassification = SystemMetadata;
OptionCaption = 'Disabled,To Shopify,From Shopify';
OptionMembers = " ","To Shopify","From Shopify";
}
field(13; "Sync Item Extended Text"; boolean)
{
Caption = 'Sync Item Extended Text';
DataClassification = SystemMetadata;
}
field(14; "Sync Item Attributes"; boolean)
{
Caption = 'Sync Item Attributes';
DataClassification = SystemMetadata;
}
field(15; "Sync Item Marketing Text"; Boolean)
{
Caption = 'Sync Item Marketing Text';
DataClassification = SystemMetadata;
}
field(21; "Auto Create Orders"; Boolean)
{
Caption = 'Auto Create Orders';
DataClassification = SystemMetadata;
trigger OnValidate()
var
ErrorInfo: ErrorInfo;
begin
if Rec."Return and Refund Process" = "Shpfy ReturnRefund ProcessType"::"Auto Create Credit Memo" then
if not Rec."Auto Create Orders" then begin
ErrorInfo.FieldNo(Rec.FieldNo("Auto Create Orders"));
ErrorInfo.ErrorType := ErrorType::Client;
ErrorInfo.RecordId := Rec.RecordId;
ErrorInfo.Message := StrSubstNo(AutoCreateErrorMsg, Rec.FieldCaption("Auto Create Orders"), Rec.FieldCaption("Return and Refund Process"), Rec."Return and Refund Process");
Error(ErrorInfo);
end;
end;
}
field(22; "Auto Create Unknown Items"; Boolean)
{
Caption = 'Auto Create Unknown Items';
DataClassification = SystemMetadata;
}
field(23; "Auto Create Unknown Customers"; Boolean)
{
Caption = 'Auto Create Unknown Customers';
DataClassification = SystemMetadata;
}
field(24; "Customer Template Code"; Code[10])
{
Caption = 'Customer Template Code';
DataClassification = SystemMetadata;
TableRelation = "Config. Template Header".Code where("Table Id" = const(18));
ValidateTableRelation = true;
ObsoleteReason = 'Replaced by "Customer Templ. Code"';
ObsoleteState = Removed;
ObsoleteTag = '25.0';
}
field(25; "Product Collection"; Option)
{
Caption = 'Product Collection';
DataClassification = SystemMetadata;
OptionCaption = ' ,Tax Group,VAT Prod. Posting Group';
OptionMembers = " ","Tax Group","VAT Prod. Posting Group";
}
field(27; "Shopify Order No. on Doc. Line"; Boolean)
{
Caption = 'Shopify Order No. on Doc. Line';
DataClassification = CustomerContent;
}
field(28; "Customer Import From Shopify"; enum "Shpfy Customer Import Range")
{
Caption = 'Customer Import from Shopify';
DataClassification = CustomerContent;
InitValue = WithOrderImport;
}
field(29; "Export Customer To Shopify"; Boolean)
{
Caption = 'Export Customer to Shopify';
DataClassification = CustomerContent;
InitValue = true;
ObsoleteReason = 'Replaced with action "Add Customer to Shopify" in Shopify Customers page.';
#if not CLEAN24
ObsoleteState = Pending;
ObsoleteTag = '24.0';
#else
ObsoleteState = Removed;
ObsoleteTag = '27.0';
#endif
}
field(30; "Shopify Can Update Customer"; Boolean)
{
Caption = 'Shopify Can Update Customers';
DataClassification = CustomerContent;
InitValue = false;
trigger OnValidate()
begin
if "Shopify Can Update Customer" then
"Can Update Shopify Customer" := false;
end;
}
field(31; "Can Update Shopify Customer"; Boolean)
{
Caption = 'Can Update Shopify Customers';
DataClassification = CustomerContent;
InitValue = false;
trigger OnValidate()
begin
if "Can Update Shopify Customer" then
"Shopify Can Update Customer" := false;
end;
}
field(32; "Name Source"; enum "Shpfy Name Source")
{
Caption = 'Name Source';
DataClassification = CustomerContent;
InitValue = CompanyName;
}
field(33; "Name 2 Source"; enum "Shpfy Name Source")
{
Caption = 'Name 2 Source';
DataClassification = CustomerContent;
InitValue = FirstAndLastName;
}
field(34; "Contact Source"; enum "Shpfy Name Source")
{
Caption = 'Contact Source';
DataClassification = CustomerContent;
InitValue = FirstAndLastName;
ValuesAllowed = FirstAndLastName, LastAndFirstName, None;
}
field(35; "County Source"; enum "Shpfy County Source")
{
Caption = 'County Source';
DataClassification = CustomerContent;
InitValue = Code;
}
field(36; "Default Customer No."; Code[20])
{
Caption = 'Default Customer No.';
DataClassification = CustomerContent;
TableRelation = Customer;
}
field(37; "UoM as Variant"; Boolean)
{
Caption = 'UoM as Variant';
DataClassification = CustomerContent;
trigger OnValidate()
begin
if "UoM as Variant" and ("Option Name for UoM" = '') then
"Option Name for UoM" := 'Unit of Measure';
end;
}
field(38; "Option Name for UoM"; Text[50])
{
Caption = 'Variant Option Name for UoM';
DataClassification = CustomerContent;
trigger OnValidate()
begin
if "Option Name for UoM" = '' then
"UoM as Variant" := false;
end;
}
field(39; "Shopify Can Update Items"; Boolean)
{
Caption = 'Shopify Can Update Items';
DataClassification = CustomerContent;
InitValue = false;
trigger OnValidate()
begin
if "Shopify Can Update Items" then
"Can Update Shopify Products" := false;
end;
}
field(40; "Can Update Shopify Products"; Boolean)
{
Caption = 'Can Update Shopify Products';
DataClassification = CustomerContent;
InitValue = false;
trigger OnValidate()
begin
if "Can Update Shopify Products" then
"Shopify Can Update Items" := false;
end;
}
field(41; "Variant Prefix"; Code[5])
{
Caption = 'Variant Prefix';
DataClassification = CustomerContent;
InitValue = 'V_';
}
field(42; "Inventory Tracked"; Boolean)
{
Caption = 'Inventory Tracked';
DataClassification = CustomerContent;
}
field(43; "Default Inventory Policy"; Enum "Shpfy Inventory Policy")
{
Caption = 'Default Inventory Policy';
DataClassification = CustomerContent;
InitValue = CONTINUE;
}
field(44; "Allow Background Syncs"; Boolean)
{
Caption = 'Allow Background Syncs';
DataClassification = CustomerContent;
InitValue = true;
}
field(47; "Tip Account"; Code[20])
{
Caption = 'Tip Account';
DataClassification = SystemMetadata;
TableRelation = "G/L Account"."No.";
ValidateTableRelation = true;
trigger OnValidate()
var
GLAccount: Record "G/L Account";
begin
if GLAccount.Get("Tip Account") then
CheckGLAccount(GLAccount);
end;
}
field(48; "Sold Gift Card Account"; Code[20])
{
Caption = 'Sold Gift Card Account';
DataClassification = SystemMetadata;
TableRelation = "G/L Account"."No.";
ValidateTableRelation = true;
trigger OnValidate()
var
GLAccount: Record "G/L Account";
begin
if GLAccount.Get("Sold Gift Card Account") then
CheckGLAccount(GLAccount);
end;
}
field(49; "Customer Mapping Type"; enum "Shpfy Customer Mapping")
{
Caption = 'Customer Mapping Type';
DataClassification = CustomerContent;
}
field(50; "Status for Created Products"; Enum "Shpfy Cr. Prod. Status Value")
{
Caption = 'Status for Created Products';
DataClassification = CustomerContent;
}
field(51; "Action for Removed Products"; Enum "Shpfy Remove Product Action")
{
Caption = 'Action for Removed Products and Blocked Items';
DataClassification = CustomerContent;
}
field(52; "Currency Code"; Code[10])
{
Caption = 'Currency Code';
DataClassification = CustomerContent;
TableRelation = Currency.Code;
trigger OnValidate()
var
CurrencyExchangeRate: Record "Currency Exchange Rate";
begin
if "Currency Code" <> '' then begin
CurrencyExchangeRate.SetRange("Currency Code", "Currency Code");
if CurrencyExchangeRate.IsEmpty() then
Error(CurrencyExchangeRateNotDefinedErr);
end;
end;
}
field(53; "Gen. Bus. Posting Group"; Code[20])
{
Caption = 'Gen. Bus. Posting Group';
DataClassification = CustomerContent;
TableRelation = "Gen. Business Posting Group";
}
field(54; "VAT Bus. Posting Group"; Code[20])
{
Caption = 'VAT Bus. Posting Group';
DataClassification = CustomerContent;
TableRelation = "VAT Business Posting Group";
}
field(55; "Tax Area Code"; Code[20])
{
Caption = 'Tax Area Code';
DataClassification = CustomerContent;
TableRelation = "Tax Area";
}
field(56; "Tax Liable"; Boolean)
{
Caption = 'Tax Liable';
DataClassification = CustomerContent;
}
field(57; "VAT Country/Region Code"; Code[10])
{
Caption = 'VAT Country/Region Code';
DataClassification = CustomerContent;
TableRelation = "Country/Region";
}
field(58; "Customer Posting Group"; Code[20])
{
Caption = 'Customer Posting Group';
DataClassification = CustomerContent;
TableRelation = "Customer Posting Group";
}
field(59; "Prices Including VAT"; Boolean)
{
Caption = 'Prices Including VAT';
DataClassification = CustomerContent;
}
field(60; "Auto Release Sales Orders"; Boolean)
{
Caption = 'Auto Release Sales Orders';
DataClassification = CustomerContent;
InitValue = true;
}
field(61; "Allow Line Disc."; Boolean)
{
Caption = 'Allow Line Disc.';
DataClassification = CustomerContent;
}
field(62; "Customer Templ. Code"; Code[20])
{
Caption = 'Customer Template Code';
DataClassification = SystemMetadata;
TableRelation = "Customer Templ.".Code;
ValidateTableRelation = true;
}
field(63; "Item Templ. Code"; Code[20])
{
Caption = 'Item Template Code';
DataClassification = SystemMetadata;
TableRelation = "Item Templ.".Code;
ValidateTableRelation = true;
}
field(70; "Return and Refund Process"; Enum "Shpfy ReturnRefund ProcessType")
{
Caption = 'Return and Refund Process';
DataClassification = CustomerContent;
InitValue = "Import Only";
trigger OnValidate()
var
ErrorInfo: ErrorInfo;
AutoCreateErrorMsg: Label 'You need to turn "%1" on if you want to set "%2" to the value of "%3".', Comment = '%1 = Field Caption of "Auto Create Orders", %2 = Field Caption of "Return and Refund Process", %3 = Field Value of "Return and Refund Process"';
begin
if Rec."Return and Refund Process" = "Shpfy ReturnRefund ProcessType"::"Auto Create Credit Memo" then
if not Rec."Auto Create Orders" then begin
ErrorInfo.FieldNo(Rec.FieldNo("Return and Refund Process"));
ErrorInfo.ErrorType := ErrorType::Client;
ErrorInfo.RecordId := Rec.RecordId;
ErrorInfo.Message := StrSubstNo(AutoCreateErrorMsg, Rec.FieldCaption("Auto Create Orders"), Rec.FieldCaption("Return and Refund Process"), Rec."Return and Refund Process");
Error(ErrorInfo);
end;
end;
}
field(73; "Return Location"; Code[10])
{
Caption = 'Default Return Location';
DataClassification = CustomerContent;
TableRelation = Location where("Use As In-Transit" = const(false));
}
field(75; "Refund Acc. non-restock Items"; Code[20])
{
Caption = 'Refund Account non-restock Items';
DataClassification = CustomerContent;
TableRelation = "G/L Account"."No.";
trigger OnValidate()
var
GLAccount: Record "G/L Account";
begin
if GLAccount.Get("Refund Acc. non-restock Items") then
CheckGLAccount(GLAccount);
end;
}
field(76; "Refund Account"; Code[20])
{
Caption = 'Refund Account';
DataClassification = CustomerContent;
TableRelation = "G/L Account"."No.";
trigger OnValidate()
var
GLAccount: Record "G/L Account";
begin
if GLAccount.Get("Refund Account") then
CheckGLAccount(GLAccount);
end;
}
field(100; "Collection Last Export Version"; BigInteger)
{
Caption = 'Collection Last Export Version';
DataClassification = SystemMetadata;
Editable = false;
Access = Internal;
ObsoleteReason = 'Not used. Moved to "Shpfy Synchronization Info" table.';
ObsoleteTag = '24.0';
ObsoleteState = Removed;
}
field(101; "Collection Last Import Version"; BigInteger)
{
Caption = 'Collection Last Import Version';
DataClassification = SystemMetadata;
Editable = false;
Access = Internal;
ObsoleteReason = 'Not used. Moved to "Shpfy Synchronization Info" table.';
ObsoleteTag = '24.0';
ObsoleteState = Removed;
}
field(102; "Product Last Export Version"; BigInteger)
{
Caption = 'Product Last Export Version';
DataClassification = SystemMetadata;
Editable = false;
Access = Internal;
ObsoleteReason = 'Not used. Moved to "Shpfy Synchronization Info" table.';
ObsoleteTag = '24.0';
ObsoleteState = Removed;
}
field(103; "Product Last Import Version"; BigInteger)
{
Caption = 'Product Last Import Version';
DataClassification = SystemMetadata;
Editable = false;
Access = Internal;
ObsoleteReason = 'Not used. Moved to "Shpfy Synchronization Info" table.';
ObsoleteTag = '24.0';
ObsoleteState = Removed;
}
#pragma warning disable AS0004
field(104; "SKU Mapping"; Enum "Shpfy SKU Mapping")
#pragma warning restore AS0004
{
Caption = 'SKU Mapping';
DataClassification = SystemMetadata;
}
field(105; "SKU Field Separator"; Code[10])
{
Caption = 'SKU Field Separator';
DataClassification = SystemMetadata;
InitValue = '|';
}
field(106; "Tax Area Priority"; Enum "Shpfy Tax By")
{
Caption = 'Tax Area Priority';
DataClassification = CustomerContent;
Description = 'Choose in which order the system try to find the county for the tax area.';
}
field(107; "Allow Outgoing Requests"; Boolean)
{
Caption = 'Allow Outgoing Requests';
DataClassification = SystemMetadata;
InitValue = true;
}
field(108; "Order Created Webhooks"; Boolean)
{
Caption = 'Order Created Webhooks';
DataClassification = SystemMetadata;
trigger OnValidate()
var
ShpfyWebhooksMgt: Codeunit "Shpfy Webhooks Mgt.";
begin
if "Order Created Webhooks" then
ShpfyWebhooksMgt.EnableOrderCreatedWebhook(Rec)
else
ShpfyWebhooksMgt.DisableOrderCreatedWebhook(Rec, CompanyName());
end;
}
field(109; "Order Created Webhook User"; Code[50])
{
Caption = 'Order Created Webhook User';
DataClassification = EndUserIdentifiableInformation;
Editable = false;
TableRelation = User."User Name";
}
field(110; "Fulfillment Service Activated"; Boolean)
{
Caption = 'Fulfillment Service Activated';
DataClassification = SystemMetadata;
Description = 'Indicates whether the Shopify Fulfillment Service is activated.';
}
field(111; "Order Created Webhook User Id"; Guid)
{
Caption = 'Order Created Webhook User Id';
DataClassification = EndUserIdentifiableInformation;
Editable = false;
TableRelation = User;
trigger OnValidate()
var
User: Record User;
begin
if User.Get("Order Created Webhook User Id") then
"Order Created Webhook User" := User."User Name";
end;
}
field(112; "Order Created Webhook Id"; Text[500])
{
Caption = 'Order Created Webhook Id';
DataClassification = SystemMetadata;
Editable = false;
}
field(113; "Logging Mode"; Enum "Shpfy Logging Mode")
{
Caption = 'Logging Mode';
DataClassification = SystemMetadata;
trigger OnValidate()
begin
if "Logging Mode" = "Logging Mode"::All then
EnableShopifyLogRetentionPolicySetup();
end;
}
field(114; "Bulk Operation Webhook User Id"; Guid)
{
Caption = 'Bulk Operation Webhook User Id';
DataClassification = EndUserIdentifiableInformation;
Editable = false;
TableRelation = User;
}
field(115; "Bulk Operation Webhook Id"; Text[500])
{
Caption = 'Bulk Operation Webhook Id';
DataClassification = SystemMetadata;
Editable = false;
}
field(116; "Sync Prices"; Boolean)
{
Caption = 'Sync Prices with Products';
DataClassification = SystemMetadata;
InitValue = true;
}
field(117; "B2B Enabled"; Boolean)
{
Caption = 'B2B Enabled';
DataClassification = SystemMetadata;
}
field(118; "Can Update Shopify Companies"; Boolean)
{
Caption = 'Can Update Shopify Companies';
DataClassification = CustomerContent;
InitValue = false;
trigger OnValidate()
begin
if "Can Update Shopify Companies" then
"Shopify Can Update Companies" := false;
end;
}
field(119; "Default Contact Permission"; Enum "Shpfy Default Cont. Permission")
{
Caption = 'Default Contact Permission';
DataClassification = CustomerContent;
InitValue = "Ordering Only";
}
field(120; "Auto Create Catalog"; Boolean)
{
Caption = 'Auto Create Catalog';
DataClassification = CustomerContent;
}
field(121; "Company Import From Shopify"; Enum "Shpfy Company Import Range")
{
Caption = 'Company Import from Shopify';
DataClassification = CustomerContent;
InitValue = WithOrderImport;
}
field(122; "Shopify Can Update Companies"; Boolean)
{
Caption = 'Shopify Can Update Companies';
DataClassification = CustomerContent;
InitValue = false;
trigger OnValidate()
begin
if "Shopify Can Update Companies" then
"Can Update Shopify Companies" := false;
end;
}
field(123; "Auto Create Unknown Companies"; Boolean)
{
Caption = 'Auto Create Unknown Companies';
DataClassification = CustomerContent;
}
field(124; "Send Shipping Confirmation"; Boolean)
{
Caption = 'Send Shipping Confirmation';
DataClassification = CustomerContent;
InitValue = true;
}
field(125; "Default Company No."; Code[20])
{
Caption = 'Default Company No.';
DataClassification = CustomerContent;
TableRelation = Customer;
}
field(126; "Company Mapping Type"; Enum "Shpfy Company Mapping")
{
Caption = 'Company Mapping Type';
DataClassification = CustomerContent;
}
field(127; "Replace Order Attribute Value"; Boolean)
{
Caption = 'Replace Order Attribute Value';
DataClassification = SystemMetadata;
InitValue = true;
ObsoleteReason = 'This feature will be enabled by default with version 27.0.';
#if not CLEAN24
ObsoleteState = Pending;
ObsoleteTag = '24.0';
#else
ObsoleteState = Removed;
ObsoleteTag = '27.0';
#endif
#if not CLEAN24
trigger OnValidate()
begin
if "Replace Order Attribute Value" then
UpdateOrderAttributes(Rec.Code);
end;
#endif
}
field(128; "Return Location Priority"; Enum "Shpfy Return Location Priority")
{
Caption = 'Return Location Priority';
DataClassification = CustomerContent;
}
field(200; "Shop Id"; Integer)
{
DataClassification = SystemMetadata;
}
}
keys
{
key(PK; Code)
{
Clustered = true;
}
key(Idx1; "Shop Id") { }
}
trigger OnDelete()
var
ShpfyWebhooksMgt: Codeunit "Shpfy Webhooks Mgt.";
begin
ShpfyWebhooksMgt.DisableOrderCreatedWebhook(Rec, CompanyName());
end;
var
InvalidShopUrlErr: Label 'The URL must refer to the internal shop location at myshopify.com. It must not be the public URL that customers use, such as myshop.com.';
CurrencyExchangeRateNotDefinedErr: Label 'The specified currency must have exchange rates configured. If your online shop uses the same currency as Business Central then leave the field empty.';
AutoCreateErrorMsg: Label 'You cannot turn "%1" off if "%2" is set to the value of "%3".', Comment = '%1 = Field Caption of "Auto Create Orders", %2 = Field Caption of "Return and Refund Process", %3 = Field Value of "Return and Refund Process"';
[Scope('OnPrem')]
internal procedure GetAccessToken() Result: SecretText
var
AuthenticationMgt: Codeunit "Shpfy Authentication Mgt.";
Store: Text;
begin
Rec.Testfield(Enabled, true);
Store := GetStoreName();
if Store <> '' then
exit(AuthenticationMgt.GetAccessToken(Store));
end;
[Scope('OnPrem')]
internal procedure RequestAccessToken()
var
AuthenticationMgt: Codeunit "Shpfy Authentication Mgt.";
Store: Text;
begin
Store := GetStoreName();
if Store <> '' then
AuthenticationMgt.InstallShopifyApp(Store);
end;
[Scope('OnPrem')]
internal procedure HasAccessToken(): Boolean
var
AuthenticationMgt: Codeunit "Shpfy Authentication Mgt.";
Store: Text;
begin
Store := GetStoreName();
if Store <> '' then
exit(AuthenticationMgt.AccessTokenExist(Store));
end;
internal procedure TestConnection(): Boolean
var
CommunicationMgt: Codeunit "Shpfy Communication Mgt.";
begin
CommunicationMgt.SetShop(Rec);
CommunicationMgt.ExecuteGraphQL('{"query":"query { app { id } }"}');
exit(true);
end;
internal procedure GetStoreName() Store: Text
begin
Store := "Shopify URL".ToLower();
if Store.Contains(':') then
Store := Store.Split(':').Get(2);
Store := Store.TrimStart('/').TrimEnd('/');
end;
/// <summary>
/// Calc Shop Id.
/// </summary>
internal procedure CalcShopId()
var
Shop: Record "Shpfy Shop";
Hash: Codeunit "Shpfy Hash";
begin
if "Shopify URL" = '' then
"Shop Id" := 0;
"Shop Id" := Hash.CalcHash("Shopify URL");
Shop.SetRange("Shop Id", "Shop Id");
Shop.SetFilter("Shopify URL", '<>%1', "Shopify URL");
Shop.SetCurrentKey("Shop Id");
while not Shop.IsEmpty do begin
"Shop Id" += 1;
Shop.SetRange("Shop Id", "Shop Id");
end;
end;
internal procedure GetEmptySyncTime(): DateTime
begin
exit(CreateDateTime(20040101D, 0T));
end;
internal procedure GetLastSyncTime(Type: Enum "Shpfy Synchronization Type"): DateTime
var
SynchronizationInfo: Record "Shpfy Synchronization Info";
begin
if Type = "Shpfy Synchronization Type"::Orders then begin
if Rec."Shop Id" = 0 then begin
Rec.CalcShopId();
Rec.Modify();
end;
if SynchronizationInfo.Get(Format(Rec."Shop Id"), Type) then
if SynchronizationInfo."Last Sync Time" = 0DT then
exit(GetEmptySyncTime())
else
exit(SynchronizationInfo."Last Sync Time");
end;
if SynchronizationInfo.Get(Rec.Code, Type) then
if SynchronizationInfo."Last Sync Time" = 0DT then
exit(GetEmptySyncTime())
else
exit(SynchronizationInfo."Last Sync Time");
exit(GetEmptySyncTime());
end;
internal procedure SetLastSyncTime(Type: Enum "Shpfy Synchronization Type")
begin
SetLastSyncTime(Type, CurrentDateTime);
end;
internal procedure SetLastSyncTime(Type: Enum "Shpfy Synchronization Type"; ToDateTime: DateTime)
var
SynchronizationInfo: Record "Shpfy Synchronization Info";
ShopCode: Code[20];
begin
if Type = "Shpfy Synchronization Type"::Orders then
ShopCode := Format(Rec."Shop Id")
else
ShopCode := Rec.Code;
if SynchronizationInfo.Get(ShopCode, Type) then begin
SynchronizationInfo."Last Sync Time" := ToDateTime;
SynchronizationInfo.Modify();
end else begin
Clear(SynchronizationInfo);
SynchronizationInfo."Shop Code" := ShopCode;
SynchronizationInfo."Synchronization Type" := Type;
SynchronizationInfo."Last Sync Time" := ToDateTime;
SynchronizationInfo.Insert();
end;
end;
internal procedure CheckGLAccount(GLAccount: Record "G/L Account")
begin
GLAccount.TestField("Account Type", GLAccount."Account Type"::Posting);
GLAccount.TestField("Direct Posting", true);
GLAccount.TestField(Blocked, false);
end;
internal procedure CopyPriceCalculationFieldsFromCustomerTempl(TemplateCode: Code[20])
var
CustomerTempl: Record "Customer Templ.";
begin
if TemplateCode = '' then
exit;
if not CustomerTempl.Get(TemplateCode) then
exit;
Rec."Gen. Bus. Posting Group" := CustomerTempl."Gen. Bus. Posting Group";
Rec."VAT Bus. Posting Group" := CustomerTempl."VAT Bus. Posting Group";
Rec."Tax Area Code" := CustomerTempl."Tax Area Code";
Rec."Tax Liable" := CustomerTempl."Tax Liable";
Rec."VAT Country/Region Code" := CustomerTempl."Country/Region Code";
Rec."Customer Posting Group" := CustomerTempl."Customer Posting Group";
Rec."Prices Including VAT" := CustomerTempl."Prices Including VAT";
Rec."Allow Line Disc." := CustomerTempl."Allow Line Disc.";
Rec.Modify();
end;
local procedure EnableShopifyLogRetentionPolicySetup()
var
RetentionPolicySetup: Record "Retention Policy Setup";
JobQueueEntry: Record "Job Queue Entry";
begin
if not TaskScheduler.CanCreateTask() then
exit;
if not (JobQueueEntry.ReadPermission() and JobQueueEntry.WritePermission()) then
exit;
if not RetentionPolicySetup.Get(Database::"Shpfy Log Entry") then
exit;
if RetentionPolicySetup.Enabled then
exit;
RetentionPolicySetup.Validate(Enabled, true);
RetentionPolicySetup.Modify(true);
end;
internal procedure GetB2BEnabled(): Boolean;
var
CommunicationMgt: Codeunit "Shpfy Communication Mgt.";
JsonHelper: Codeunit "Shpfy Json Helper";
JResponse: JsonToken;
JItem: JsonToken;
begin
CommunicationMgt.SetShop(Rec);
JResponse := CommunicationMgt.ExecuteGraphQL('{"query":"query { shop { name plan { partnerDevelopment shopifyPlus } } }"}');
if JResponse.SelectToken('$.data.shop.plan', JItem) then
if JItem.IsObject then begin
if JsonHelper.GetValueAsBoolean(JItem, 'shopifyPlus') then
exit(true);
if JsonHelper.GetValueAsBoolean(JItem, 'partnerDevelopment') then
exit(true);