dunga-dunga-backend/justfile at main · trackedout/dunga-dunga-backend · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
set dotenv-load # Load environment variables from .env file

_default:
    @just --list --unsorted

_sync-now node:
  rsync -rav --delete --mkpath --rsync-path="sudo rsync" ./src/ {{node}}:/tracked-out/dunga-dunga/src/

dev-sync node="burn":
  #!/bin/bash
  just _sync-now {{node}}

  # ins inotify-tools
  while inotifywait -r -e modify,create,delete src; do
    just _sync-now {{node}}
  done

dev_docker_image := "dunga-dunga-backend:dev"
prod_docker_image := "dunga-dunga-backend:latest"

registry_dev := "registry-dev.trackedout.org/dunga-dunga"
registry_prod := "registry.trackedout.org/dunga-dunga"

# Build dev image
build-dev-image:
  docker build -t {{dev_docker_image}} -f Dockerfile-dev .

# Build prod image
build-prod-image:
  docker build -t {{prod_docker_image}} -f Dockerfile .

# Push dev image to k3s registry
push-dev-image:
  docker tag {{dev_docker_image}} {{registry_dev}}:dev
  docker push {{registry_dev}}:dev

# Push prod image to k3s registry
push-prod-image:
  docker tag {{prod_docker_image}} {{registry_prod}}:latest
  docker push {{registry_prod}}:latest

# Push both dev and prod images
push-images: push-dev-image push-prod-image

# Build and push dev images
build-and-push-dev: build-dev-image push-dev-image

# Build and push prod images
build-and-push-prod: build-prod-image push-prod-image

# Build, push, and deploy to k3s cluster - dev
dev-deploy: build-and-push-dev
  k3s kubectl --context=burn patch deployment -n davybones dunga-dunga -p '{"spec":{"template":{"spec":{"containers":[{"name":"dunga-dunga","image": "{{registry_dev}}:dev", "imagePullPolicy":"Always"}]}}}}'
  k3s kubectl --context=burn rollout restart -n davybones deployment/dunga-dunga

# Build, push, and deploy to k3s cluster - prod
# prod-deploy: build-and-push-prod
#   k3s kubectl patch deployment -n davybones dunga-dunga -p '{"spec":{"template":{"spec":{"containers":[{"name":"dunga-dunga","image": "{{registry_prod}}:latest", "imagePullPolicy":"Always"}]}}}}'
#   k3s kubectl rollout restart -n davybones deployment/dunga-dunga