Add service info (#691)

Author: balanza

lib/wanda_web/controllers/info_controller.ex

@@ -0,0 +1,29 @@
+defmodule WandaWeb.InfoController do
+  use WandaWeb, :controller
+  use OpenApiSpex.ControllerSpecs
+
+  alias WandaWeb.Schemas.V1.Info
+
+  operation :info,
+    summary: "Wanda service information.",
+    tags: ["Checks/Operations Platform"],
+    description:
+      "This endpoint returns information about this Wanda instance for service discovery purposes, including name and version",
+    security: [],
+    responses: [
+      ok:
+        {"This response provides service discovery information about the current Wanda instance.",
+         "application/json", Info}
+    ]
+
+  def info(conn, _) do
+    version = to_string(Application.spec(:wanda, :vsn))
+
+    conn
+    |> put_status(200)
+    |> json(%{
+      name: "wanda",
+      version: version
+    })
+  end
+end

lib/wanda_web/router.ex

@@ -146,6 +146,7 @@ defmodule WandaWeb.Router do
 
   scope "/api", WandaWeb do
     pipe_through :api
+    get "/", InfoController, :info
     get "/healthz", HealthController, :health
     get "/readyz", HealthController, :ready
   end

lib/wanda_web/schemas/v1/info.ex

@@ -0,0 +1,46 @@
+defmodule WandaWeb.Schemas.V1.Info do
+  @moduledoc """
+  Info response schema.
+  """
+
+  alias OpenApiSpex.Operation
+  alias OpenApiSpex.Schema
+
+  require OpenApiSpex
+
+  OpenApiSpex.schema(
+    %Schema{
+      title: "InfoV1",
+      description:
+        "This response provides service discovery information about the current Wanda instance.",
+      type: :object,
+      example: %{
+        name: "wanda",
+        version: "2.0.0"
+      },
+      additionalProperties: false,
+      properties: %{
+        name: %Schema{
+          description: "The service name.",
+          type: :string,
+          example: "wanda"
+        },
+        version: %Schema{
+          description: "The version of the running Wanda application.",
+          type: :string,
+          example: "2.0.0"
+        }
+      },
+      required: [:name, :version]
+    },
+    struct?: false
+  )
+
+  def response do
+    Operation.response(
+      "This response provides service discovery information about the current Wanda instance.",
+      "application/json",
+      __MODULE__
+    )
+  end
+end

test/wanda_web/controllers/info_controller_test.exs

@@ -0,0 +1,32 @@
+defmodule WandaWeb.InfoControllerTest do
+  @moduledoc false
+
+  use WandaWeb.ConnCase, async: true
+
+  import OpenApiSpex.TestAssertions
+
+  alias WandaWeb.Schemas.Unversioned.ApiSpec
+
+  setup do
+    %{api_spec: ApiSpec.spec()}
+  end
+
+  describe "Info" do
+    test "returns the current Wanda instance information", %{
+      conn: conn,
+      api_spec: api_spec
+    } do
+      response =
+        conn
+        |> get("/api")
+        |> json_response(200)
+
+      assert %{
+               "name" => "wanda",
+               "version" => _
+             } = response
+
+      assert_schema(response, "InfoV1", api_spec)
+    end
+  end
+end