Question: Where do inputs for benchmark_n_body come from?

[Leibniz1697]

Hi. I am learning to use Julia GPU programming for many body simulations. I am trying to understand how to use PointNeightbors for calculating neighbor lists. Looking through the tests and benchmarks it is not clear to me where the inputs come from for the line:

PointNeighbors.jl/benchmarks/n_body.jl

Line 15 in ab74c02

function benchmark_n_body(neighborhood_search, coordinates_;

[efaulhaber]

I apologize for the non-existent documentation. It's on my list.
To run the benchmarks, currently, you basically have to go through the plots.jl script. I changed this in #118.

Here is a simple usage example, also with GPUs. This is similar to the count neighbors benchmark.

using PointNeighbors

# Generate grid of particles
n_particles_per_dimension = (100, 100)
n_particles = prod(n_particles_per_dimension)
coordinates = Array{Float32}(undef, 2, n_particles)
cartesian_indices = CartesianIndices(n_particles_per_dimension)

for i in axes(coordinates, 2)
    coordinates[:, i] .= Tuple(cartesian_indices[i])
end

# `FullGridCellList` requires a bounding box
min_corner = minimum(coordinates, dims=2)
max_corner = maximum(coordinates, dims=2)
search_radius = 3.0f0
cell_list = FullGridCellList(; search_radius, min_corner, max_corner)
nhs = GridNeighborhoodSearch{2}(; search_radius, cell_list)

# Initialize the NHS to find neighbors in `coordinates` of particles in `coordinates`
initialize!(nhs, coordinates, coordinates)

# Simple example: just count the neighbors of each particle
n_neighbors = zeros(Int, n_particles)

# Use a function for performance reasons
function count_neighbors!(n_neighbors, coordinates, nhs)
    n_neighbors .= 0
    foreach_point_neighbor(coordinates, coordinates, nhs) do i, j, pos_diff, distance
        n_neighbors[i] += 1
    end
end
count_neighbors!(n_neighbors, coordinates, nhs)

# Use your GPU's backend, e.g. CUDABackend()
using Metal, Adapt
backend = MetalBackend()

# Convert data structures to the GPU
coordinates_gpu = adapt(backend, coordinates)
nhs_gpu = adapt(backend, nhs)
n_neighbors_gpu = adapt(backend, n_neighbors)

# Count neighbors on the GPU
n_neighbors_gpu .= 0
count_neighbors!(n_neighbors_gpu, coordinates_gpu, nhs_gpu)

I hope this helps. Feel free to ask more equations, and I try to incorporate everything in the docs.

[Leibniz1697]

Hi! Thanks for getting back to me. This was very helpful and seems to work well!

[Leibniz1697]

Would it be possible for you to show how to modify this example for periodic boundary conditions? I am running into some error messages when I try to use the periodicity keyword in FullGridCellList and the periodic_box keyword in GridNeighborhoodSearch.

[efaulhaber]

I just realized the docstring of the FullGridCellList is outdated. This kwarg does not exist anymore.
You only need to pass a periodic box to the NHS:

using PointNeighbors

# Generate grid of particles
n_particles_per_dimension = (100, 100)
n_particles = prod(n_particles_per_dimension)
coordinates = Array{Float32}(undef, 2, n_particles)
cartesian_indices = CartesianIndices(n_particles_per_dimension)

for i in axes(coordinates, 2)
    coordinates[:, i] .= Tuple(cartesian_indices[i])
end

# Create a periodic box for periodicity
periodic_box = PeriodicBox(min_corner=(0.0f0, 0.0f0), max_corner=(100.0f0, 100.0f0))

# `FullGridCellList` requires a bounding box
min_corner = minimum(coordinates, dims=2)
max_corner = maximum(coordinates, dims=2)
search_radius = 3.0f0
cell_list = FullGridCellList(; search_radius, min_corner, max_corner)
nhs = GridNeighborhoodSearch{2}(; search_radius, cell_list, periodic_box)

# Initialize the NHS to find neighbors in `coordinates` of particles in `coordinates`
initialize!(nhs, coordinates, coordinates)

# Simple example: just count the neighbors of each particle
n_neighbors = zeros(Int, n_particles)

# Use a function for performance reasons
function count_neighbors!(n_neighbors, coordinates, nhs)
    n_neighbors .= 0
    foreach_point_neighbor(coordinates, coordinates, nhs) do i, j, pos_diff, distance
        n_neighbors[i] += 1
    end
end
count_neighbors!(n_neighbors, coordinates, nhs)

Note that the type used for the periodic box must match the type of the search_radius.
I just added a more descriptive error message for that, mentioned it in the docs, and updated the incorrect docstring in #128.

[Leibniz1697]

Hey! Thanks again for your help. I got it to work.