Merging incoming hardware serial MIDI into stream

[jonvog]

Hi everyone,
total newbie here, so excuse me if I am missing the obvious.

I have a small circuit for controlling CCs up and running (Teensy LC). It sends the CC data via USB MIDI to the computer, works fine so far. Now I would like to integrate a DIN MIDI port that receives serial MIDI data from a keyboard, merge it with the CC data so it becomes one USB MIDI device.

I guess I have to use MIDI_Pipes in a similar fashion to this one: MIDI_Pipes-Routing.ino

But I don't quite get how/where to specify at which pin the DIN port is connected in the first place.
Can somebody point me to it? Thanks a lot in advance!

This is my sketch, for context:

#include <Control_Surface.h> // Include the Control Surface library
 
// Instantiate a MIDI over USB interface.
USBMIDI_Interface midi;
 
// Instantiate an array of CCPotentiometer objects
CCPotentiometer potentiometers[] = {
  {A0,        // Analog pin connected to potentiometer 1 - Links oben
       0x16}, // Controller number of the first potentiometer (hex) - CC22
  {A1, 0x17}, // poti rechts oben - CC23   
  {A2, 0x18}, // poti links unten - CC24
  {A3, 0x19}, // poti rechts unten - CC25
  {A4, 0x01}, // fader 1 - CC1
  {A5, 0x0B}, // fader 2 - CC11
  {A6, 0x15}, // fader 3 - CC21
  {A7, 0x02}, // fader 4 - CC2
};
 
void setup() {
  Control_Surface.begin(); // Initialize Control Surface
}
 
void loop() {
  Control_Surface.loop(); // Update the Control Surface
}

[jonvog]

Ok, I figured I had to learn how the serial ports behave in the first place. Now I think I have everything setup properly, but as soon as I integrate the MIDI pipes, I don't get anymore MIDI data whatsoever. With the above code all the pots work fine. I also added the PB which works more or less fine (I still need to map it properly).
This is how I extended the code, anyone has an idea what I am doing wrong?

#include <Control_Surface.h> // Include the Control Surface library
 
// Instantiate a MIDI over USB interface.
USBMIDI_Interface midiusb;
HardwareSerialMIDI_Interface midiser = Serial1;

// Instantiate MIDI Pipes
MIDI_PipeFactory<1> pipes;
 
// Instantiate an array of CCPotentiometer objects
CCPotentiometer potentiometers[] = {
  {A0,        // Analog pin connected to potentiometer 1 - Links oben
       0x16}, // Controller number of the first potentiometer (hex) - CC22
  {A1, 0x17}, // poti rechts oben - CC23   
  {A2, 0x18}, // poti links unten - CC24
  {A3, 0x19}, // poti rechts unten - CC25
  {A4, 0x01}, // fader 1 - CC1
  {A5, 0x0B}, // fader 2 - CC11
  {A6, 0x15}, // fader 3 - CC21
  {A7, 0x02}, // fader 4 - CC2
};
PBPotentiometer potentiometer = {
  A8,        // Analog pin connected to potentiometer
  CHANNEL_1, // MIDI Channel 1 
};
 
void setup() {
  midiser >> pipes >> midiusb; // all incoming midi from Serial is sent to USB
  Control_Surface.begin(); // Initialize Control Surface
  
}
 
void loop() {
  Control_Surface.loop(); // Update the Control Surface
}

[tttapa]

Control Surface always uses the “default MIDI interface”. If the default MIDI interface was configured explicitly using midi.setAsDefault(), that interface is used. If it wasn't set explicitly, or if the default MIDI interface no longer exists, the newest MIDI interface, the one that was constructed most recently, is used.
If you only define one MIDI interface, that's the one Control Surface will use, but if there are multiple MIDI interfaces in your program, I recommend setting the default MIDI interface explicitly:

void setup() {
  midiser >> pipes >> midiusb; // all incoming midi from Serial is sent to USB
  midiusb.setAsDefault(); // (must be done before initializing Control Surface)
  Control_Surface.begin(); // Initialize Control Surface 
}

[jonvog]

Thanks a lot! I had an error in my circuit so probably that was the problem in the first place, but now it works in any case. Great!