supabase-py/flake.nix at main · usagi-epta/supabase-py · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
{
  description = "realtime-py: a Realtime python client.";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    pyproject-nix = {
      url = "github:pyproject-nix/pyproject.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    uv2nix = {
      url = "github:pyproject-nix/uv2nix";
      inputs.pyproject-nix.follows = "pyproject-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    pyproject-build-systems = {
      url = "github:pyproject-nix/build-system-pkgs";
      inputs.pyproject-nix.follows = "pyproject-nix";
      inputs.uv2nix.follows = "uv2nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { nixpkgs, pyproject-nix, uv2nix, pyproject-build-systems, ... }: let
    for-all-systems = f:
      nixpkgs.lib.genAttrs [
        "x86_64-linux"
        "aarch64-darwin"
        "aarch64-linux"
        "x86_64-darwin"
      ] (system: f nixpkgs.legacyPackages.${system});

    dev-tools = pkgs: [
      pkgs.supabase-cli
      pkgs.uv
      pkgs.gnumake
      pkgs.docker
    ];
    workspace = uv2nix.lib.workspace.loadWorkspace { workspaceRoot = ./.; };

    workspace-overlay = workspace.mkPyprojectOverlay {
      sourcePreference = "wheel";
    };

    editable-overlay = workspace.mkEditablePyprojectOverlay {
      root = "$REPO_ROOT";
    };

    pyproject-overlay = final: prev: {
      ruamel-yaml-clib = prev.ruamel-yaml-clib.overrideAttrs (old: {
        nativeBuildInputs = old.nativeBuildInputs ++ [
          (final.resolveBuildSystem {
            setuptools = [];
          })
        ];
      });

    };

    python-for = pkgs: let
      extensions = pkgs.lib.composeManyExtensions [
        pyproject-build-systems.overlays.default
        workspace-overlay
        editable-overlay
        pyproject-overlay
      ];
      base-python = pkgs.callPackage pyproject-nix.build.packages {
        python = pkgs.python311;
      };
    in base-python.overrideScope extensions;
  in {
    devShells = for-all-systems (pkgs: let
      python = python-for pkgs;
      python-env = python.mkVirtualEnv "supabase-py" workspace.deps.all;
    in {
      default = pkgs.mkShell {
        env = {
          # Don't create venv using uv
          UV_NO_SYNC = "1";

          # Force uv to use nixpkgs Python interpreter
          UV_PROJECT_ENVIRONMENT = python-env;
          UV_PYTHON = pkgs.python311.interpreter;

          # Prevent uv from downloading managed Python's
          UV_PYTHON_DOWNLOADS = "never";
        };
        shellHook = ''
          # Undo dependency propagation by nixpkgs.
          unset PYTHONPATH
          export REPO_ROOT=$(git rev-parse --show-toplevel)
        '';
        packages = [ python-env ] ++ (dev-tools pkgs);
      };
    });
  };
}