lazytf/flake.nix at main · ushiradineth/lazytf · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
{
  description = "lazytf: terminal UI for Terraform plans";

  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs =
    {
      self,
      flake-utils,
      nixpkgs,
    }:
    (flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs { inherit system; };
        appVersion = pkgs.lib.strings.removeSuffix "\n" (builtins.readFile ./VERSION);
        lazytf = pkgs.buildGoModule {
          pname = "lazytf";
          version = appVersion;

          src = ./.;
          vendorHash = "sha256-twmrMrtvUVzDiB8FHgDiAf9gbsCR+/mCZfmMucXWTcs=";
          proxyVendor = true;
          go = pkgs.go_1_25;
          doCheck = false;

          env = {
            GOTOOLCHAIN = "local";
          };

          ldflags = [
            "-s"
            "-w"
            "-X github.com/ushiradineth/lazytf/internal/consts.Version=${appVersion}"
          ];

          meta = with pkgs.lib; {
            description = "Terminal UI for reviewing Terraform plans";
            homepage = "https://github.com/ushiradineth/lazytf";
            license = licenses.mit;
            platforms = platforms.unix;
            mainProgram = "lazytf";
          };
        };
      in
      {
        packages.default = lazytf;
        packages.lazytf = lazytf;

        apps.default = flake-utils.lib.mkApp {
          drv = lazytf;
        };

        devShells.default = pkgs.mkShell {
          buildInputs = [
            pkgs.go

            pkgs.gopls
            pkgs.gofumpt
            pkgs.goimports-reviser
            pkgs.golines
            pkgs.golangci-lint
            pkgs.govulncheck
            pkgs.go-tools
            pkgs.gow

            pkgs.vimPlugins.nvim-treesitter-parsers.go
            pkgs.vimPlugins.nvim-treesitter-parsers.gomod
          ];
        };
      }
    ))
    // {
      overlays.default = final: prev: {
        lazytf = self.packages.${final.system}.default;
      };

      nixosModules.default = import ./nix/modules/nixos.nix;
      homeManagerModules.default = import ./nix/modules/home-manager.nix;
    };
}