jgnash/build.gradle at master · valnaumov/jgnash · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
plugins {
    id 'com.github.ben-manes.versions' version '0.17.0'
}

allprojects {

    // jgnash-help is not a compiled sub-project
    if (!it.name.startsWith('jgnash-help')) {
        apply plugin: 'java'
    }

    apply plugin: 'findbugs'

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    group = 'jgnash'
    version = '2.36.1'

    project.ext {
        junitVersion = '5.3.1'
        junitextensionsVersion = '2.3.0'

        picocliVersion = '3.5.2'

        apachePoiVersion = '4.0.0'
        commonsCsvVersion = '1.6'
        commonsTextVersion = '1.6'

        h2Version = '1.4.197'
        hsqldbVersion = '2.4.1'

        xstreamVersion = '1.4.11.1'

        hibernateVersion = '5.3.7.Final'
        hikariVersion = '3.2.0'

        dynamicJasperVersion = '5.1.1'
        jasperReportsVersion = '6.4.3'
        itextVersion = '2.1.7.js6'

        nettyVersion = '4.1.31.Final'

        slf4jVersion = '1.8.0-beta2'

        jfreeChartVersion = '1.0.19'
        substanceVersion = '7.3'
        swingxVersion = '1.6.5-1'

        awaitilityVersion = '3.1.2'
    }

    tasks.withType(FindBugs) {
        reports {
            xml.enabled = false
            html.enabled = true
        }
    }

    findbugs {
        ignoreFailures = true
        excludeFilter = file("$rootProject.projectDir/findbugs-exclude-filter.xml")
    }
}

subprojects {
    repositories {
        mavenCentral()
        jcenter()
        mavenLocal()
        maven { url "http://jaspersoft.jfrog.io/jaspersoft/third-party-ce-artifacts/" }
    }

    // jgnash-help is not a compiled sub-project
    if (!it.name.startsWith('jgnash-help')) {
        dependencies {

            testCompile group: 'org.junit.jupiter', name: 'junit-jupiter-api', version: junitVersion
            testCompile group: 'org.junit.jupiter', name: 'junit-jupiter-params', version: junitVersion
            testRuntime group: 'org.junit.jupiter', name: 'junit-jupiter-engine', version: junitVersion

            testCompile group: 'io.github.glytching', name: 'junit-extensions', version: junitextensionsVersion
            testCompile group: 'org.awaitility', name: 'awaitility', version: awaitilityVersion
            testCompile group: 'org.apache.commons', name: 'commons-text', version: commonsTextVersion
        }
    }

    test {
        useJUnitPlatform()

        //we want display the following test events
        testLogging {
            events "PASSED", "STARTED", "FAILED", "SKIPPED"
            showStandardStreams = true
        }
    }
}

wrapper {
    gradleVersion = '4.10.2'
}

task distZip {
    doLast {
        ant.zip(destfile: 'jgnash-' + version + '-bin.zip', duplicate: 'preserve', update: 'false') {
            zipgroupfileset(dir: '.', includes: 'jgnash-swing/build/distributions/jGnashSwing-' + version + '.zip')
            zipgroupfileset(dir: '.', includes: 'jgnash-fx/build/distributions/jGnashFx-' + version + '.zip')
        }
    }
}

distZip.dependsOn(":jgnash-fx:distZip")
distZip.dependsOn(":jgnash-swing:distZip")