flake.nix

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";

    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    devshell = {
      url = "github:numtide/devshell";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs@{ flake-parts, ... }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      imports = [
        inputs.treefmt-nix.flakeModule
        inputs.devshell.flakeModule
      ];

      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "aarch64-darwin"
        "x86_64-darwin"
      ];
      perSystem =
        {
          config,
          self',
          inputs',
          pkgs,
          system,
          ...
        }:
        {
          treefmt = {
            programs = {
              gofmt.enable = true;
            };
          };

          devshells.default = {
            packages =
              with pkgs;
              [
                golangci-lint
                kind
                kubectl
                kubernetes-controller-tools
                kubernetes-helm
                kustomize
                operator-sdk
                vendir
              ]
              ++ (builtins.attrValues config.treefmt.build.programs);

            env =
              let
                assets = pkgs.buildEnv {
                  name = "kubebuilder-assets";
                  pathsToLink = [ "/bin" ];
                  paths = [
                    pkgs.etcd
                    pkgs.kubernetes
                  ];
                };
              in
              [
                {
                  name = "KUBEBUILDER_ASSETS";
                  value = "${assets}/bin";
                }
              ];
          };
        };
    };
}