restructure the module a bit so that the order of execution clear

should also prevent issues with apt::update being scheduled after we try
to install the package

Author: evgeni

manifests/config.pp

@@ -0,0 +1,17 @@
+# @summary Configure the Alloy service
+#
+# @api private
+class grafana_alloy::config (
+  Optional[String[1]] $config = undef,
+) {
+  assert_private()
+
+  if $config {
+    file { '/etc/alloy/config.alloy':
+      content => $config,
+      mode    => '0640',
+      owner   => 'root',
+      group   => 'alloy',
+    }
+  }
+}

manifests/init.pp

@@ -5,23 +5,14 @@
 class grafana_alloy (
   Optional[String[1]] $config = undef,
 ) {
-  require grafana_alloy::repo
-  package { 'alloy': }
+  contain grafana_alloy::repo
+  contain grafana_alloy::install
 
-  if $config {
-    file { '/etc/alloy/config.alloy':
-      content => $config,
-      mode    => '0640',
-      owner   => 'root',
-      group   => 'alloy',
-      require => Package['alloy'],
-      notify  => Service['alloy'],
-    }
+  class { 'grafana_alloy::config':
+    config => $config,
   }
 
-  service { 'alloy':
-    ensure  => 'running',
-    enable  => true,
-    require => Package['alloy'],
-  }
+  contain grafana_alloy::service
+
+  Class['grafana_alloy::repo'] -> Class['grafana_alloy::install'] -> Class['grafana_alloy::config'] ~> Class['grafana_alloy::service']
 }

manifests/install.pp

@@ -0,0 +1,8 @@
+# @summary Install the Alloy package
+#
+# @api private
+class grafana_alloy::install () {
+  assert_private()
+
+  package { 'alloy': }
+}

manifests/service.pp

@@ -0,0 +1,11 @@
+# @summary Manage the Alloy service
+#
+# @api private
+class grafana_alloy::service () {
+  assert_private()
+
+  service { 'alloy':
+    ensure => 'running',
+    enable => true,
+  }
+}