odoo-nix/flake.nix at main · vwh/odoo-nix · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
{
  description = "Odoo 18 development environment";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, utils }:
    utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs { inherit system; };
        python = pkgs.python312;
        pyPkgs = pkgs.python312Packages;
        nodejs = pkgs.nodejs_22;
        nodePkgs = pkgs.nodePackages;
      in
      {
        devShells.default = pkgs.mkShell {
          name = "odoo-dev";
          venvDir = "./.venv";

          buildInputs = with pkgs; [
            # Python environment
            python
            pyPkgs.venvShellHook
            pyPkgs.psycopg2 # Python PostgreSQL connector
            pyPkgs.inotify # Odoo filesystem watcher

            # Node.js environment
            nodejs
            nodePkgs.less #  Odoo frontend asset compilation
            nodePkgs.rtlcss # Odoo frontend asset compilation

            # Database
            postgresql_16

            # Build tools
            sassc # Odoo SCSS compilation
            libsass

            # Development tools
            just # Command runner

            # System libraries
            libxml2
            libxslt
            libjpeg
            libpng
            zlib
            freetype
            wkhtmltopdf
            openldap
            cyrus_sasl

            # Fonts
            dejavu_fonts
            freefont_ttf
            noto-fonts
            inconsolata
            font-awesome
            roboto
            ghostscript
          ];

          postVenvCreation = ''
            unset SOURCE_DATE_EPOCH
            # Set environment variables for C extension builds
            export LDAP_INCLUDES="${pkgs.openldap.dev}/include"
            export LDAP_LIBS="${pkgs.openldap.out}/lib"
            export SASL_INCLUDES="${pkgs.cyrus_sasl.dev}/include"
            export SASL_LIBS="${pkgs.cyrus_sasl.out}/lib"

            pip install -r odoo-requirements.txt
          '';

          postShellHook = ''
            unset SOURCE_DATE_EPOCH

            # Set environment variables for C extension builds (in case they're needed later)
            export LDAP_INCLUDES="${pkgs.openldap.dev}/include"
            export LDAP_LIBS="${pkgs.openldap.out}/lib"
            export SASL_INCLUDES="${pkgs.cyrus_sasl.dev}/include"
            export SASL_LIBS="${pkgs.cyrus_sasl.out}/lib"

            # PostgreSQL setup
            export PGDATA=$PWD/.pgdata
            export PGHOST=127.0.0.1
            export PGPORT=5433

            # initdb once
            if [ ! -f "$PGDATA/PG_VERSION" ]; then
              echo "› initdb → $PGDATA"
              mkdir -p "$PGDATA"
              initdb --encoding=UTF8 \
                    --username="$USER" \
                    --auth-local=trust \
                    --auth-host=trust \
                    "$PGDATA"
            fi

            # start if not already running
            if ! pg_ctl -D "$PGDATA" status >/dev/null 2>&1; then
              echo "› pg_ctl start → $PGHOST:$PGPORT (TCP only)"
              pg_ctl -D "$PGDATA" \
                    -o "-F -p $PGPORT -h $PGHOST -k $PGDATA" \
                    -l "$PGDATA/server.log" \
                    start || {
                echo "PostgreSQL failed to start. Check .pgdata/server.log"
                echo "Continuing without PostgreSQL..."
              }
            fi

            export PGDATABASE=odoo-dev
            echo "Python venv: $(which python)"
            echo "PostgreSQL: $PGHOST:$PGPORT"
          '';
        };
      }
    );
}