wiremock-grpc-extension/wiremock-grpc-extension-jetty/build.gradle at e2181ebe098cc684310be490a08125d0f76596b9 · wiremock/wiremock-grpc-extension · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
buildscript {
  repositories {
    maven {
      url "https://oss.sonatype.org"
    }
    mavenCentral()
  }
}

plugins {
  id 'java-library'
  id 'signing'
  id 'maven-publish'
  id 'idea'
  id 'eclipse'
  id 'project-report'
  id 'com.diffplug.spotless' version '8.3.0'
  id 'com.vanniktech.maven.publish.base' version '0.36.0'
}

repositories {
  mavenLocal()
  mavenCentral()
}

group 'org.wiremock'

dependencies {
  api project(":wiremock-grpc-extension-core")
  api "org.wiremock:wiremock-core:$versions.wiremock"
  api "org.wiremock:wiremock-jetty:$versions.wiremock"

  api platform("io.grpc:grpc-bom:$versions.grpc")
  api "io.grpc:grpc-api"
  api "com.google.protobuf:protobuf-java:$versions.protobuf"
  api 'jakarta.servlet:jakarta.servlet-api:6.1.0'

  implementation "io.grpc:grpc-servlet-jakarta"

  implementation platform('org.eclipse.jetty:jetty-bom:12.1.6')
  implementation platform('org.eclipse.jetty.ee11:jetty-ee11-bom:12.1.7')
  implementation 'org.eclipse.jetty.ee11:jetty-ee11-servlet'
  implementation 'org.eclipse.jetty:jetty-util'

  testImplementation(platform('org.junit:junit-bom:6.0.3'))
  testImplementation 'org.junit.jupiter:junit-jupiter-api'
  testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
  testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine'
  testImplementation 'org.hamcrest:hamcrest:3.0'

  testRuntimeOnly "io.grpc:grpc-okhttp"

  testImplementation testFixtures(project(":wiremock-grpc-extension-core"))
  testImplementation project(':wiremock-grpc-extension-core').sourceSets.bookings.output
}

task sourcesJar(type: Jar, dependsOn: classes) {
  archiveClassifier.set('sources')
  from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
  archiveClassifier.set('javadoc')
  from javadoc.destinationDir
}

task testJar(type: Jar, dependsOn: testClasses) {
  archiveClassifier.set('tests')
  from sourceSets.test.output
}

publishing {
  repositories {
    maven {
      name = "GitHubPackages"
      url = "https://maven.pkg.github.com/wiremock/wiremock-grpc-extension"
      credentials {
        username = System.getenv("GITHUB_ACTOR")
        password = System.getenv("GITHUB_TOKEN")
      }
    }
  }

  publications {
    jetty(MavenPublication) { publication ->
      from components.java
      artifact sourcesJar
      artifact javadocJar
      artifact testJar

      pom.packaging 'jar'
      pom.withXml {
        asNode().appendNode('description', 'Mock gRPC services with WireMock')
        asNode().children().last() + pomInfo
      }
    }
  }
}

mavenPublishing {
  publishToMavenCentral()
}

signing {
  // Docs: https://github.com/wiremock/community/blob/main/infra/maven-central.md
  required {
    !version.toString().contains("SNAPSHOT") && (gradle.taskGraph.hasTask("uploadArchives") || gradle.taskGraph.hasTask("publish") || gradle.taskGraph.hasTask("publishToMavenLocal"))
  }
  def signingKey = providers.environmentVariable("OSSRH_GPG_SECRET_KEY").orElse("").get()
  def signingPassphrase = providers.environmentVariable("OSSRH_GPG_SECRET_KEY_PASSWORD").orElse("").get()
  if (!signingKey.isEmpty() && !signingPassphrase.isEmpty()) {
    println "Using PGP key from env vars"
    useInMemoryPgpKeys(signingKey, signingPassphrase)
  } else {
    println "Using default PGP key"
  }

  sign publishing.publications
}

test {
  useJUnitPlatform()
  testLogging {
    events "PASSED", "FAILED", "SKIPPED"
    exceptionFormat "full"
  }
}

assemble.dependsOn clean, jar

publishJettyPublicationToMavenLocal.dependsOn jar
publishJettyPublicationToGitHubPackagesRepository.dependsOn jar
publishJettyPublicationToMavenCentralRepository.dependsOn jar

task localRelease {
  dependsOn clean, assemble, publishToMavenLocal
}