easyeffects/PKGBUILD_AUR at master · wwmm/easyeffects · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
# Maintainer: robertfoster
# Contributor: Bleuzen <supgesu@gmail.com>
# Contributor: Filipe Laíns (FFY00) <lains@archlinux.org>
# Contributor: Wellington <wellingtonwallace@gmail.com>

pkgname=easyeffects-git
pkgver=8.0.0.r0.g2a3986ca4
pkgrel=1
pkgdesc='Simple audio effects'
arch=(x86_64 i686 arm armv6h armv7h aarch64)
url='https://github.com/wwmm/easyeffects'
license=('GPL3')
depends=(
  'kcolorscheme'
  'kirigami'
  'kirigami-addons'
  'kiconthemes'
  'kconfigwidgets'
  'qqc2-desktop-style'
  'breeze-icons'
  'qt6-base'
  'qt6-graphs'
  'pipewire-pulse'
  'lilv'
  'libsndfile'
  'zita-convolver'
  'libebur128'
  'rnnoise'
  'soundtouch'
  'libbs2b'
  'nlohmann-json'
  'tbb'
  'speexdsp'
  'gsl'
  'webrtc-audio-processing'
  'libmysofa'
)
makedepends=('cmake' 'extra-cmake-modules' 'git' 'ninja' 'intltool' 'appstream' 'ladspa')
optdepends=('calf: limiter, exciter, bass enhancer and others'
            'lsp-plugins: equalizer, compressor, delay, loudness'
            'zam-plugins: maximizer'
            'mda.lv2: bass loudness'
            'libdeep_filter_ladspa: noise remover'
            'breeze: kde breeze style')
conflicts=("${pkgname%%-git}")
provides=("${pkgname%%-git}")
source=("$pkgname::git+${url}")
# source=("$pkgname::git+${url}#branch=eeqt")
sha512sums=('SKIP')

pkgver() {
  cd "$pkgname"
  printf "%s" "$(git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g')"
}

build() {
  local cmake_options=(
    -B build
    -S $pkgname
    -W no-dev
    -D CMAKE_BUILD_TYPE=None
    -D CMAKE_INSTALL_PREFIX=/usr
    -G Ninja
  )
  cmake "${cmake_options[@]}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}